mirror of
git://git.yoctoproject.org/poky
synced 2026-09-30 21:13:24 +00:00
80990ab718
Changelog: ========== wireless-regdb: update regulatory database based on preceding changes wireless-regdb: Update regulatory rules for Australia (AU) for June 2023 wireless-regdb: Update regulatory info for Türkiye (TR) wireless-regdb: Update regulatory rules for Egypt (EG) from March 2022 guidel... wireless-regdb: Update regulatory rules for Philippines (PH) (From OE-Core rev: c1ae47b562460e82d94a94a2009c4cb50aa1daa9) Signed-off-by: Wang Mingyu <wangmy@fujitsu.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> (cherry picked from commit 2f5edb6904bf16a9c52a9b124aeb5297487cd716) Signed-off-by: Steve Sakoman <steve@sakoman.com>
44 lines
1.6 KiB
BlitzBasic
44 lines
1.6 KiB
BlitzBasic
SUMMARY = "Wireless Central Regulatory Domain Database"
|
|
HOMEPAGE = "https://wireless.wiki.kernel.org/en/developers/regulatory/crda"
|
|
SECTION = "net"
|
|
LICENSE = "ISC"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=07c4f6dea3845b02a18dc00c8c87699c"
|
|
|
|
SRC_URI = "https://www.kernel.org/pub/software/network/${BPN}/${BP}.tar.xz"
|
|
SRC_URI[sha256sum] = "26d4c2a727cc59239b84735aad856b7c7d0b04e30aa5c235c4f7f47f5f053491"
|
|
|
|
inherit bin_package allarch
|
|
|
|
do_install() {
|
|
install -d -m0755 ${D}${nonarch_libdir}/crda
|
|
install -d -m0755 ${D}${sysconfdir}/wireless-regdb/pubkeys
|
|
install -m 0644 regulatory.bin ${D}${nonarch_libdir}/crda/regulatory.bin
|
|
install -m 0644 sforshee.key.pub.pem ${D}${sysconfdir}/wireless-regdb/pubkeys/sforshee.key.pub.pem
|
|
|
|
install -m 0644 -D regulatory.db ${D}${nonarch_base_libdir}/firmware/regulatory.db
|
|
install -m 0644 regulatory.db.p7s ${D}${nonarch_base_libdir}/firmware/regulatory.db.p7s
|
|
}
|
|
|
|
# Install static regulatory DB in /lib/firmware for kernel to load.
|
|
# This requires Linux kernel >= v4.15.
|
|
# For kernel <= v4.14, inherit the kernel_wireless_regdb.bbclass
|
|
# (in meta-networking) in kernel's recipe.
|
|
PACKAGES = "${PN}-static ${PN}"
|
|
RCONFLICTS:${PN} = "${PN}-static"
|
|
|
|
FILES:${PN}-static = " \
|
|
${nonarch_base_libdir}/firmware/regulatory.db \
|
|
${nonarch_base_libdir}/firmware/regulatory.db.p7s \
|
|
"
|
|
|
|
# Native users might want to use the source of regulatory DB.
|
|
# This is for example used by Linux kernel <= v4.14 and
|
|
# kernel_wireless_regdb.bbclass in meta-networking.
|
|
do_install:append:class-native() {
|
|
install -m 0644 -D db.txt ${D}${libdir}/crda/db.txt
|
|
}
|
|
|
|
RSUGGESTS:${PN} = "crda"
|
|
|
|
BBCLASSEXTEND = "native"
|