mirror of
git://git.yoctoproject.org/poky
synced 2026-10-02 16:07:07 +00:00
2d760d2d61
Fix some failed info like: | ./test/test-bus: relocation error: ./test/test-bus: symbol | _dbus_threads_init_debug, version LIBDBUS_PRIVATE_1.10.10 not defined | in file libdbus-1.so.3 with link time reference | FAIL: test/test-bus In run-ptest, LD_LIBRARY_PATH is set to /usr/lib, but when multilib is enabled, /usr/lib64 will be used. fix by replace with correct path. (From OE-Core rev: d1bdf962dc3f121066bd7efb451dd9072b881718) Signed-off-by: Changqing Li <changqing.li@windriver.com> Signed-off-by: Ross Burton <ross.burton@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
84 lines
3.1 KiB
BlitzBasic
84 lines
3.1 KiB
BlitzBasic
SUMMARY = "D-Bus test package (for D-bus functionality testing only)"
|
|
HOMEPAGE = "http://dbus.freedesktop.org"
|
|
SECTION = "base"
|
|
LICENSE = "AFL-2 | GPLv2+"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=10dded3b58148f3f1fd804b26354af3e \
|
|
file://dbus/dbus.h;beginline=6;endline=20;md5=7755c9d7abccd5dbd25a6a974538bb3c"
|
|
|
|
DEPENDS = "dbus glib-2.0"
|
|
|
|
RDEPENDS_${PN} += "make"
|
|
RDEPENDS_${PN}-dev = ""
|
|
|
|
SRC_URI = "http://dbus.freedesktop.org/releases/dbus/dbus-${PV}.tar.gz \
|
|
file://tmpdir.patch \
|
|
file://run-ptest \
|
|
file://python-config.patch \
|
|
file://clear-guid_from_server-if-send_negotiate_unix_f.patch \
|
|
"
|
|
|
|
SRC_URI[md5sum] = "c3e12b4206e2a7da39d7cc42567790ef"
|
|
SRC_URI[sha256sum] = "4b693d24976258c3f2fa9cc33ad9288c5fbfa7a16481dbd9a8a429f7aa8cdcf7"
|
|
|
|
S="${WORKDIR}/dbus-${PV}"
|
|
FILESEXTRAPATHS =. "${FILE_DIRNAME}/dbus:"
|
|
|
|
inherit autotools pkgconfig gettext ptest upstream-version-is-even
|
|
|
|
EXTRA_OECONF_X = "${@bb.utils.contains('DISTRO_FEATURES', 'x11', '--with-x', '--without-x', d)}"
|
|
EXTRA_OECONF_X_class-native = "--without-x"
|
|
|
|
EXTRA_OECONF = "--enable-tests \
|
|
--enable-modular-tests \
|
|
--enable-installed-tests \
|
|
--enable-checks \
|
|
--enable-asserts \
|
|
--enable-verbose-mode \
|
|
--enable-largefile \
|
|
--disable-xml-docs \
|
|
--disable-doxygen-docs \
|
|
--disable-libaudit \
|
|
--with-dbus-test-dir=${PTEST_PATH} \
|
|
${EXTRA_OECONF_X}"
|
|
|
|
EXTRA_OECONF_append_class-target = " SYSTEMCTL=${base_bindir}/systemctl"
|
|
|
|
PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'systemd x11', d)}"
|
|
PACKAGECONFIG_class-native = ""
|
|
PACKAGECONFIG_class-nativesdk = ""
|
|
|
|
PACKAGECONFIG[systemd] = "--enable-systemd --with-systemdsystemunitdir=${systemd_system_unitdir},--disable-systemd --without-systemdsystemunitdir,systemd"
|
|
PACKAGECONFIG[x11] = "--with-x --enable-x11-autolaunch,--without-x --disable-x11-autolaunch, virtual/libx11 libsm"
|
|
PACKAGECONFIG[user-session] = "--enable-user-session --with-systemduserunitdir=${systemd_user_unitdir},--disable-user-session"
|
|
|
|
do_install() {
|
|
:
|
|
}
|
|
|
|
do_install_ptest() {
|
|
install -d ${D}${PTEST_PATH}/test
|
|
l="shell printf refs syslog marshal syntax corrupt dbus-daemon dbus-daemon-eavesdrop loopback relay \
|
|
variant uid-permissions syntax spawn sd-activation names monitor message fdpass "
|
|
for i in $l; do install ${B}/test/.libs/test-$i ${D}${PTEST_PATH}/test; done
|
|
|
|
l="bus bus-system bus-launch-helper"
|
|
for i in $l; do install ${B}/bus/.libs/test-$i ${D}${PTEST_PATH}/test; done
|
|
|
|
cp -r ${B}/test/data ${D}${PTEST_PATH}/test
|
|
install ${B}/dbus/.libs/test-dbus ${D}${PTEST_PATH}/test
|
|
|
|
install -d ${D}${PTEST_PATH}/test/.libs
|
|
cp -a ${B}/dbus/.libs/*.so* ${D}${PTEST_PATH}/test/.libs
|
|
|
|
# Remove build host references...
|
|
find "${D}${PTEST_PATH}/test/data" \( -name *.service -o -name *.conf -o -name "*.aaprofile" \) -type f -exec \
|
|
sed -i \
|
|
-e 's:${B}:${PTEST_PATH}:g' \
|
|
{} +
|
|
sed -i -e 's;@PTEST_PATH@;${PTEST_PATH};g' ${D}${PTEST_PATH}/run-ptest
|
|
}
|
|
|
|
RDEPENDS_${PN}-ptest += "bash"
|
|
|
|
PRIVATE_LIBS_${PN}-ptest = "libdbus-1.so.3"
|