mirror of
git://git.yoctoproject.org/poky
synced 2026-10-01 13:58:27 +00:00
166e5bdd7e
barebox-tools needs to be updated in lockstep with barebox, and was already once erroneously updated to 2024.10 without barebox itself. Particularly, this change puts PV into .inc as well for both recipes. This will allow AUH to produce correct update patches, as barebox recipe is mutually exclusive with u-boot, and so isn't handled by AUH. mesa-gl recipe uses a similar trick with mesa. (From OE-Core rev: 555a637d467364f896b72436a83b118e29ee5550) Signed-off-by: Alexander Kanavin <alex@linutronix.de> Signed-off-by: Mathieu Dubois-Briand <mathieu.dubois-briand@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
56 lines
1.1 KiB
BlitzBasic
56 lines
1.1 KiB
BlitzBasic
SUMMARY = "barebox bootloader tools"
|
|
|
|
require barebox-common.inc
|
|
|
|
LICENSE = "GPL-2.0-only"
|
|
|
|
DEPENDS = "bison-native flex-native libusb1"
|
|
|
|
S = "${WORKDIR}/barebox-${PV}"
|
|
B = "${WORKDIR}/build"
|
|
|
|
inherit pkgconfig
|
|
|
|
EXTRA_OEMAKE = " \
|
|
ARCH=sandbox \
|
|
CROSS_COMPILE=${TARGET_PREFIX} -C ${S} O=${B} \
|
|
CROSS_PKG_CONFIG=pkg-config \
|
|
CC='${CC}' \
|
|
LD='${LD}' \
|
|
"
|
|
|
|
do_compile:class-target () {
|
|
export userccflags="${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS}"
|
|
export userldflags="${TARGET_LDFLAGS}${TOOLCHAIN_OPTIONS}"
|
|
oe_runmake targettools_defconfig
|
|
oe_runmake scripts
|
|
}
|
|
|
|
do_compile:class-native () {
|
|
oe_runmake hosttools_defconfig
|
|
oe_runmake scripts
|
|
}
|
|
|
|
BAREBOX_TOOLS = " \
|
|
bareboxenv \
|
|
bareboxcrc32 \
|
|
kernel-install \
|
|
bareboximd \
|
|
omap3-usb-loader \
|
|
omap4_usbboot \
|
|
imx/imx-usb-loader \
|
|
"
|
|
|
|
BAREBOX_TOOLS_SUFFIX = ""
|
|
BAREBOX_TOOLS_SUFFIX:class-target = "-target"
|
|
|
|
do_install () {
|
|
install -d ${D}${bindir}
|
|
|
|
for tool in ${BAREBOX_TOOLS}; do
|
|
install -m 0755 scripts/${tool}${BAREBOX_TOOLS_SUFFIX} ${D}${bindir}/${tool##*/}
|
|
done
|
|
}
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|