mirror of
git://git.yoctoproject.org/poky
synced 2026-09-29 12:44:27 +00:00
ee276e50e5
(From OE-Core rev: 5aa78e651ddef8a19768fa713993568cd3cc2a13) Signed-off-by: Ross Burton <ross.burton@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> Signed-off-by: Adrian Bunk <bunk@stusta.de> Signed-off-by: Armin Kuster <akuster808@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
46 lines
1.8 KiB
BlitzBasic
46 lines
1.8 KiB
BlitzBasic
SUMMARY = "An HTTP library implementation in C"
|
|
HOMEPAGE = "https://wiki.gnome.org/Projects/libsoup"
|
|
BUGTRACKER = "https://bugzilla.gnome.org/"
|
|
SECTION = "x11/gnome/libs"
|
|
LICENSE = "LGPLv2"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=5f30f0716dfdd0d91eb439ebec522ec2"
|
|
|
|
DEPENDS = "glib-2.0 glib-2.0-native libxml2 sqlite3 intltool-native libpsl"
|
|
|
|
SHRT_VER = "${@d.getVar('PV').split('.')[0]}.${@d.getVar('PV').split('.')[1]}"
|
|
|
|
SRC_URI = "${GNOME_MIRROR}/libsoup/${SHRT_VER}/libsoup-${PV}.tar.xz \
|
|
file://0001-Do-not-enforce-no-introspection-when-cross-building.patch \
|
|
"
|
|
SRC_URI[md5sum] = "cac755dc6c6acd6e0c70007f547548f5"
|
|
SRC_URI[sha256sum] = "75ddc194a5b1d6f25033bb9d355f04bfe5c03e0e1c71ed0774104457b3a786c6"
|
|
|
|
CVE_PRODUCT = "libsoup"
|
|
|
|
S = "${WORKDIR}/libsoup-${PV}"
|
|
|
|
inherit meson gettext pkgconfig upstream-version-is-even gobject-introspection gtk-doc
|
|
|
|
# libsoup-gnome is entirely deprecated and just stubs in 2.42 onwards. Disable by default.
|
|
PACKAGECONFIG ??= ""
|
|
PACKAGECONFIG[gnome] = "-Dgnome=true,-Dgnome=false"
|
|
PACKAGECONFIG[gssapi] = "-Dgssapi=true,-Dgssapi=false,krb5"
|
|
|
|
EXTRA_OEMESON_append = " -Dvapi=false"
|
|
|
|
GTKDOC_ENABLE_FLAG = "-Ddoc=true"
|
|
GTKDOC_DISABLE_FLAG = "-Ddoc=false"
|
|
|
|
EXTRA_OEMESON_append_class-target = " ${@bb.utils.contains('GTKDOC_ENABLED', 'True', '${GTKDOC_ENABLE_FLAG}', \
|
|
'${GTKDOC_DISABLE_FLAG}', d)} "
|
|
|
|
|
|
# When built without gnome support, libsoup-2.4 will contain only one shared lib
|
|
# and will therefore become subject to renaming by debian.bbclass. Prevent
|
|
# renaming in order to keep the package name consistent regardless of whether
|
|
# gnome support is enabled or disabled.
|
|
DEBIAN_NOAUTONAME_${PN} = "1"
|
|
|
|
# glib-networking is needed for SSL, proxies, etc.
|
|
RRECOMMENDS_${PN} = "glib-networking"
|