mirror of
git://git.yoctoproject.org/poky
synced 2026-10-01 01:05:00 +00:00
e547b2c85f
busybox as well as vlock utility from meta-oe provides vlock utility
which can conflict when with kbd if pam is a enabled distro_feature
Fixes image build errors
update-alternatives: Error: not linking <rootfs>/usr/bin/vlock to /bin/busybox.suid since <rootfs>/usr/bin/vlock exists and is not a link
ERROR: yoe-qt5-wayland-image-1.0-r0 do_rootfs: Postinstall scriptlets of ['busybox'] have failed. If the intention is to defer them to first boot,
then please place them into pkg_postinst_ontarget_${PN} ().
Deferring to first boot via 'exit 1' is no longer supported.
(From OE-Core rev: d00349526f5727fdff9b40c6139d95bd75af213d)
Signed-off-by: Khem Raj <raj.khem@gmail.com>
The vlock doesn't exist if PAM isn't enabled.
Signed-off-by: Hongxu Jia <hongxu.jia@windriver.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
Signed-off-by: De Huo <de.huo@windriver.com>
Signed-off-by: Armin Kuster <akuster808@gmail.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
67 lines
2.4 KiB
BlitzBasic
67 lines
2.4 KiB
BlitzBasic
SUMMARY = "Keytable files and keyboard utilities"
|
|
HOMEPAGE = "http://www.kbd-project.org/"
|
|
# everything minus console-fonts is GPLv2+
|
|
LICENSE = "GPLv2+"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=a5fcc36121d93e1f69d96a313078c8b5"
|
|
|
|
inherit autotools gettext ptest pkgconfig
|
|
|
|
RREPLACES_${PN} = "console-tools"
|
|
RPROVIDES_${PN} = "console-tools"
|
|
RCONFLICTS_${PN} = "console-tools"
|
|
|
|
SRC_URI = "${KERNELORG_MIRROR}/linux/utils/${BPN}/${BP}.tar.xz \
|
|
file://run-ptest \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'ptest', 'file://set-proper-path-of-resources.patch', '', d)} \
|
|
file://0001-configure.ac-Fix-logic-of-vlock-configure-switch.patch \
|
|
"
|
|
|
|
SRC_URI[md5sum] = "c1635a5a83b63aca7f97a3eab39ebaa6"
|
|
SRC_URI[sha256sum] = "5fd90af6beb225a9bb9b9fb414c090fba53c9a55793e172f508cd43652e59a88"
|
|
|
|
PACKAGECONFIG ?= "${@bb.utils.filter('DISTRO_FEATURES', 'pam', d)} \
|
|
${@bb.utils.contains('PTEST_ENABLED', '1', 'tests','', d)} \
|
|
"
|
|
|
|
PACKAGECONFIG[pam] = "--enable-vlock, --disable-vlock, libpam,"
|
|
PACKAGECONFIG[tests] = "--enable-tests, --disable-tests, libcheck"
|
|
|
|
do_compile_ptest() {
|
|
oe_runmake -C ${B}/tests dumpkeys-fulltable alt-is-meta
|
|
}
|
|
|
|
do_install_ptest() {
|
|
install -D ${B}/tests/Makefile ${D}${PTEST_PATH}/tests/Makefile
|
|
sed -i -e '/Makefile:/,/^$/d' -e '/%: %.in/,/^$/d' \
|
|
-e 's:--sysroot=${STAGING_DIR_TARGET}::g' \
|
|
-e 's:${DEBUG_PREFIX_MAP}::g' \
|
|
-e 's:${HOSTTOOLS_DIR}/::g' \
|
|
-e 's:${RECIPE_SYSROOT_NATIVE}::g' \
|
|
-e 's:${RECIPE_SYSROOT}::g' \
|
|
-e 's:${S}/config/missing::g' \
|
|
-e 's:${WORKDIR}::g' \
|
|
-e '/libkeymap_.*_SOURCES =/d' -e '/$(EXEEXT):/,/^$/d' ${D}${PTEST_PATH}/tests/Makefile
|
|
|
|
find ${B}/tests -executable -exec install {} ${D}${PTEST_PATH}/tests \;
|
|
find ${S}/tests \( -name \*.map -o -name \*.bin -o -name \*.output \) -exec install {} ${D}${PTEST_PATH}/tests \;
|
|
|
|
install -D -m 755 ${S}/config/test-driver ${D}${PTEST_PATH}/config/test-driver
|
|
}
|
|
|
|
PACKAGES += "${PN}-consolefonts ${PN}-keymaps ${PN}-unimaps ${PN}-consoletrans"
|
|
|
|
FILES_${PN}-consolefonts = "${datadir}/consolefonts"
|
|
FILES_${PN}-consoletrans = "${datadir}/consoletrans"
|
|
FILES_${PN}-keymaps = "${datadir}/keymaps"
|
|
FILES_${PN}-unimaps = "${datadir}/unimaps"
|
|
|
|
RDEPENDS_${PN}-ptest = "make"
|
|
|
|
inherit update-alternatives
|
|
|
|
ALTERNATIVE_${PN} = "chvt deallocvt fgconsole openvt showkey \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'pam', 'vlock','', d)}"
|
|
ALTERNATIVE_PRIORITY = "100"
|
|
|
|
BBCLASSEXTEND = "native"
|