mirror of
git://git.yoctoproject.org/poky
synced 2026-10-07 17:55:35 +00:00
29d6678fd5
Having one monolithic packages directory makes it hard to find things and is generally overwhelming. This commit splits it into several logical sections roughly based on function, recipes.txt gives more information about the classifications used. The opportunity is also used to switch from "packages" to "recipes" as used in OpenEmbedded as the term "packages" can be confusing to people and has many different meanings. Not all recipes have been classified yet, this is just a first pass at separating things out. Some packages are moved to meta-extras as they're no longer actively used or maintained. Signed-off-by: Richard Purdie <rpurdie@linux.intel.com>
81 lines
2.5 KiB
PHP
81 lines
2.5 KiB
PHP
DESCRIPTION = "Dropbear is a lightweight SSH and SCP Implementation"
|
|
HOMEPAGE = "http://matt.ucc.asn.au/dropbear/dropbear.html"
|
|
SECTION = "console/network"
|
|
|
|
# some files are from other projects and have others license terms:
|
|
# public domain, OpenSSH 3.5p1, OpenSSH3.6.1p2, PuTTY
|
|
LICENSE = "MIT"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=3a5b0c2f0d0c49dfde9558ae2036683c"
|
|
|
|
DEPENDS = "zlib"
|
|
PROVIDES = "ssh sshd"
|
|
RPROVIDES = "ssh sshd"
|
|
|
|
SRC_URI = "http://matt.ucc.asn.au/dropbear/releases/dropbear-${PV}.tar.gz \
|
|
file://urandom-xauth-changes-to-options.h.patch \
|
|
file://configure.patch \
|
|
file://fix-2kb-keys.patch \
|
|
file://allow-nopw.patch;apply=no \
|
|
file://init"
|
|
|
|
inherit autotools update-rc.d
|
|
|
|
INITSCRIPT_NAME = "dropbear"
|
|
INITSCRIPT_PARAMS = "defaults 10"
|
|
|
|
CFLAGS_prepend = " -I. "
|
|
LD = "${CC}"
|
|
|
|
SBINCOMMANDS = "dropbear dropbearkey dropbearconvert"
|
|
BINCOMMANDS = "dbclient ssh scp"
|
|
EXTRA_OEMAKE = 'MULTI=1 SCPPROGRESS=1 PROGRAMS="${SBINCOMMANDS} ${BINCOMMANDS}"'
|
|
|
|
DISTRO_TYPE = "${@base_contains("IMAGE_FEATURES", "debug-tweaks", "debug", "",d)}"
|
|
|
|
do_configure_prepend() {
|
|
if [ "x${DISTRO}" != "xfamiliar" -a "${DISTRO_TYPE}" = "debug" ]; then
|
|
oenote "WARNING: applying allow-nopw.patch which allows password-less logins!"
|
|
patch -p1 < ${WORKDIR}/allow-nopw.patch
|
|
fi
|
|
}
|
|
|
|
do_install() {
|
|
install -d ${D}${sysconfdir} \
|
|
${D}${sysconfdir}/init.d \
|
|
${D}${sysconfdir}/default \
|
|
${D}${sysconfdir}/dropbear \
|
|
${D}${bindir} \
|
|
${D}${sbindir} \
|
|
${D}${localstatedir}
|
|
|
|
install -m 0755 dropbearmulti ${D}${sbindir}/
|
|
ln -s ${sbindir}/dropbearmulti ${D}${bindir}/dbclient
|
|
|
|
for i in ${SBINCOMMANDS}
|
|
do
|
|
ln -s ./dropbearmulti ${D}${sbindir}/$i
|
|
done
|
|
cat ${WORKDIR}/init | sed -e 's,/etc,${sysconfdir},g' \
|
|
-e 's,/usr/sbin,${sbindir},g' \
|
|
-e 's,/var,${localstatedir},g' \
|
|
-e 's,/usr/bin,${bindir},g' \
|
|
-e 's,/usr,${prefix},g' > ${D}${sysconfdir}/init.d/dropbear
|
|
chmod 755 ${D}${sysconfdir}/init.d/dropbear
|
|
}
|
|
|
|
pkg_postinst () {
|
|
update-alternatives --install ${bindir}/scp scp ${sbindir}/dropbearmulti 20
|
|
update-alternatives --install ${bindir}/ssh ssh ${sbindir}/dropbearmulti 20
|
|
}
|
|
|
|
pkg_postrm_append () {
|
|
if [ -f "${sysconfdir}/dropbear/dropbear_rsa_host_key" ]; then
|
|
rm ${sysconfdir}/dropbear/dropbear_rsa_host_key
|
|
fi
|
|
if [ -f "${sysconfdir}/dropbear/dropbear_dss_host_key" ]; then
|
|
rm ${sysconfdir}/dropbear/dropbear_dss_host_key
|
|
fi
|
|
update-alternatives --remove ssh ${bindir}/dropbearmulti
|
|
update-alternatives --remove scp ${bindir}/dropbearmulti
|
|
}
|