mirror of
git://git.yoctoproject.org/poky
synced 2026-09-17 00:56:11 +00:00
14d1499e48
This also fixes the build of vboxguest drivers against the
reference kernel.
1/1 [
Author: Bruce Ashfield
Email: bruce.ashfield@gmail.com
Subject: cfg/drm: add CONFIG_DRM_TTM and CONFIG_DRM_VMWGFX
Date: Tue, 9 Sep 2025 14:14:18 -0400
drm-bochs is used as a baseline featur efor DRM that guests
may need.
We add these two options to get symbols into the kernel required
to build guest support kernel modules.
Signed-off-by: Bruce Ashfield <bruce.ashfield@gmail.com>
]
(From OE-Core rev: 153181d4cb36ec50daeab185e1ab5e42113689bd)
Signed-off-by: Bruce Ashfield <bruce.ashfield@gmail.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
80 lines
4.3 KiB
BlitzBasic
80 lines
4.3 KiB
BlitzBasic
KBRANCH ?= "v6.16/standard/base"
|
|
|
|
require recipes-kernel/linux/linux-yocto.inc
|
|
|
|
# CVE exclusions
|
|
include recipes-kernel/linux/cve-exclusion.inc
|
|
include recipes-kernel/linux/cve-exclusion_6.16.inc
|
|
|
|
# board specific branches
|
|
KBRANCH:qemuarm ?= "v6.16/standard/arm-versatile-926ejs"
|
|
KBRANCH:qemuarm64 ?= "v6.16/standard/base"
|
|
KBRANCH:qemumips ?= "v6.16/standard/mti-malta32"
|
|
KBRANCH:qemuppc ?= "v6.16/standard/qemuppc"
|
|
KBRANCH:qemuriscv64 ?= "v6.16/standard/base"
|
|
KBRANCH:qemuriscv32 ?= "v6.16/standard/base"
|
|
KBRANCH:qemux86 ?= "v6.16/standard/base"
|
|
KBRANCH:qemux86-64 ?= "v6.16/standard/base"
|
|
KBRANCH:qemuloongarch64 ?= "v6.16/standard/base"
|
|
KBRANCH:qemumips64 ?= "v6.16/standard/mti-malta64"
|
|
|
|
SRCREV_machine:qemuarm ?= "b1d9863cd54ffc3b03ee0e270c86e8c99c88462c"
|
|
SRCREV_machine:qemuarm64 ?= "01bcf423b031a36a070c7a983e45992e634fceb7"
|
|
SRCREV_machine:qemuloongarch64 ?= "01bcf423b031a36a070c7a983e45992e634fceb7"
|
|
SRCREV_machine:qemumips ?= "297e7bd12c944fd0746419990157ec1a7fb7ddf3"
|
|
SRCREV_machine:qemuppc ?= "01bcf423b031a36a070c7a983e45992e634fceb7"
|
|
SRCREV_machine:qemuriscv64 ?= "01bcf423b031a36a070c7a983e45992e634fceb7"
|
|
SRCREV_machine:qemuriscv32 ?= "01bcf423b031a36a070c7a983e45992e634fceb7"
|
|
SRCREV_machine:qemux86 ?= "01bcf423b031a36a070c7a983e45992e634fceb7"
|
|
SRCREV_machine:qemux86-64 ?= "01bcf423b031a36a070c7a983e45992e634fceb7"
|
|
SRCREV_machine:qemumips64 ?= "2459c29bf2c3d221fd6d3222c7200b368156986e"
|
|
SRCREV_machine ?= "01bcf423b031a36a070c7a983e45992e634fceb7"
|
|
SRCREV_meta ?= "29767181a0c0a97c8ba4941f6834044d9ffaed86"
|
|
|
|
# set your preferred provider of linux-yocto to 'linux-yocto-upstream', and you'll
|
|
# get the <version>/base branch, which is pure upstream -stable, and the same
|
|
# meta SRCREV as the linux-yocto-standard builds. Select your version using the
|
|
# normal PREFERRED_VERSION settings.
|
|
BBCLASSEXTEND = "devupstream:target"
|
|
SRCREV_machine:class-devupstream ?= "be15dab9a451155bdf3f5278608fe8dc67e07cc1"
|
|
PN:class-devupstream = "linux-yocto-upstream"
|
|
KBRANCH:class-devupstream = "v6.16/base"
|
|
|
|
SRC_URI = "git://git.yoctoproject.org/linux-yocto.git;name=machine;branch=${KBRANCH};protocol=https \
|
|
git://git.yoctoproject.org/yocto-kernel-cache;type=kmeta;name=meta;branch=yocto-6.16;destsuffix=${KMETA};protocol=https"
|
|
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=6bc538ed5bd9a7fc9398086aedcd7e46"
|
|
LINUX_VERSION ?= "6.16.4"
|
|
|
|
PV = "${LINUX_VERSION}+git"
|
|
|
|
KMETA = "kernel-meta"
|
|
KCONF_BSP_AUDIT_LEVEL = "1"
|
|
|
|
KERNEL_DEVICETREE:qemuarmv5 = "arm/versatile-pb.dtb"
|
|
|
|
COMPATIBLE_MACHINE = "^(qemuarm|qemuarmv5|qemuarm64|qemux86|qemuppc|qemuppc64|qemumips|qemumips64|qemux86-64|qemuriscv64|qemuriscv32|qemuloongarch64)$"
|
|
|
|
# Functionality flags
|
|
KERNEL_EXTRA_FEATURES ?= "features/netfilter/netfilter.scc"
|
|
KERNEL_FEATURES:append = " ${KERNEL_EXTRA_FEATURES}"
|
|
KERNEL_FEATURES:append:qemuall = " cfg/virtio.scc features/drm-bochs/drm-bochs.scc cfg/net/mdio.scc"
|
|
KERNEL_FEATURES:append:qemux86 = " cfg/sound.scc cfg/paravirt_kvm.scc"
|
|
KERNEL_FEATURES:append:qemux86-64 = " cfg/sound.scc cfg/paravirt_kvm.scc"
|
|
KERNEL_FEATURES:append = " ${@bb.utils.contains("TUNE_FEATURES", "mx32", " cfg/x32.scc", "", d)}"
|
|
KERNEL_FEATURES:append = " ${@bb.utils.contains("DISTRO_FEATURES", "ptest", " features/scsi/scsi-debug.scc features/nf_tables/nft_test.scc", "", d)}"
|
|
KERNEL_FEATURES:append = " ${@bb.utils.contains("DISTRO_FEATURES", "ptest", " features/gpio/mockup.scc features/gpio/sim.scc", "", d)}"
|
|
KERNEL_FEATURES:append = " ${@bb.utils.contains("KERNEL_DEBUG", "True", " features/reproducibility/reproducibility.scc features/debug/debug-btf.scc", "", d)}"
|
|
# libteam ptests from meta-oe needs it
|
|
KERNEL_FEATURES:append = " ${@bb.utils.contains("DISTRO_FEATURES", "ptest", " features/net/team/team.scc", "", d)}"
|
|
# openl2tp tests from meta-networking needs it
|
|
KERNEL_FEATURES:append = " ${@bb.utils.contains("DISTRO_FEATURES", "ptest", " cgl/cfg/net/l2tp.scc", "", d)}"
|
|
KERNEL_FEATURES:append:powerpc = " arch/powerpc/powerpc-debug.scc"
|
|
KERNEL_FEATURES:append:powerpc64 = " arch/powerpc/powerpc-debug.scc"
|
|
KERNEL_FEATURES:append:powerpc64le = " arch/powerpc/powerpc-debug.scc"
|
|
# Do not add debug info for riscv32, it fails during depmod
|
|
# ERROR: modpost: __ex_table+0x17a4 references non-executable section '.debug_loclists'
|
|
# Check again during next major version upgrade
|
|
KERNEL_FEATURES:remove:riscv32 = "features/debug/debug-kernel.scc"
|
|
INSANE_SKIP:kernel-vmlinux:qemuppc64 = "textrel"
|