mirror of
git://git.yoctoproject.org/poky
synced 2026-04-02 02:49:11 +00:00
1b94ea8b25
We've been removing PR values from recipes at upgrade time for a while. In general anyone maintaining a binary distro would end up having to curate these themselves so the values in OE-Core aren't really that useful anymore. In many ways it makes sense to clear out the remaining ones (which are mostly for 'config' recipes that are unlikely to increase in PV) and leave a clean slate for anyone implementing a binary distro config. References are left in meta-selftest since the tests there do involve them and their removal upon upgrade. (From OE-Core rev: d4c346e8ab8f3cae25d1b01c7331ed9f6d4f96ef) Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
41 lines
1.3 KiB
BlitzBasic
41 lines
1.3 KiB
BlitzBasic
SUMMARY = "Basic TCP/IP networking init scripts and configuration files"
|
|
DESCRIPTION = "This package provides high level tools to configure network interfaces"
|
|
HOMEPAGE = "http://packages.debian.org/ifupdown"
|
|
SECTION = "base"
|
|
LICENSE = "GPL-2.0-only"
|
|
LIC_FILES_CHKSUM = "file://${WORKDIR}/copyright;md5=3dd6192d306f582dee7687da3d8748ab"
|
|
|
|
inherit update-rc.d
|
|
|
|
INITSCRIPT_NAME = "networking"
|
|
INITSCRIPT_PARAMS = "start 01 2 3 4 5 . stop 80 0 6 1 ."
|
|
|
|
SRC_URI = "file://copyright \
|
|
file://init \
|
|
file://interfaces \
|
|
file://nfsroot"
|
|
|
|
S = "${WORKDIR}"
|
|
|
|
do_install () {
|
|
install -d ${D}${sysconfdir}/init.d \
|
|
${D}${sysconfdir}/network/if-pre-up.d \
|
|
${D}${sysconfdir}/network/if-up.d \
|
|
${D}${sysconfdir}/network/if-down.d \
|
|
${D}${sysconfdir}/network/if-post-down.d
|
|
install -m 0755 ${WORKDIR}/init ${D}${sysconfdir}/init.d/networking
|
|
install -m 0644 ${WORKDIR}/interfaces ${D}${sysconfdir}/network/interfaces
|
|
install -m 0755 ${WORKDIR}/nfsroot ${D}${sysconfdir}/network/if-pre-up.d
|
|
}
|
|
|
|
do_install:append:qemuall () {
|
|
# Disable network manager on machines that commonly do NFS booting
|
|
touch ${D}${sysconfdir}/network/nm-disabled-eth0
|
|
}
|
|
|
|
PACKAGE_ARCH = "${MACHINE_ARCH}"
|
|
RDEPENDS:${PN} = "netbase"
|
|
RCONFLICTS:${PN} = "netbase (< 1:5.0)"
|
|
|
|
CONFFILES:${PN} = "${sysconfdir}/network/interfaces"
|