mirror of
git://git.yoctoproject.org/poky
synced 2026-10-13 22:48:12 +00:00
95d15a3480
Changelog: ============ - Painting of COLRv1 fonts without clip boxes is now about 10 times faster. - Synthetic bold/slant of a sub font is now respected, instead of using the parent's. - Glyph extents for fonts synthetic bold/slant are now accurately calculated. - Various build fixes - New API: +hb_font_is_synthetic() +hb_font_draw_glyph_or_fail_func_t +hb_font_paint_glyph_or_fail_func_t +hb_font_funcs_set_draw_glyph_or_fail_func() +hb_font_funcs_set_paint_glyph_or_fail_func() +hb_font_draw_glyph_or_fail() +hb_font_paint_glyph_or_fail() - Deprecated API: -hb_font_draw_glyph_func_t -hb_font_paint_glyph_func_t -hb_font_funcs_set_draw_glyph_func() -hb_font_funcs_set_paint_glyph_func() (From OE-Core rev: d54d2b64e4939bb887fa88ea2436025216f313ba) Signed-off-by: Wang Mingyu <wangmy@fujitsu.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
50 lines
2.0 KiB
BlitzBasic
50 lines
2.0 KiB
BlitzBasic
SUMMARY = "Text shaping library"
|
|
DESCRIPTION = "HarfBuzz is an OpenType text shaping engine."
|
|
HOMEPAGE = "http://www.freedesktop.org/wiki/Software/HarfBuzz"
|
|
BUGTRACKER = "https://bugs.freedesktop.org/enter_bug.cgi?product=HarfBuzz"
|
|
SECTION = "libs"
|
|
LICENSE = "MIT"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=b98429b8e8e3c2a67cfef01e99e4893d \
|
|
file://src/hb-ucd.cc;beginline=1;endline=15;md5=29d4dcb6410429195df67efe3382d8bc \
|
|
"
|
|
|
|
SRC_URI = "${GITHUB_BASE_URI}/download/${PV}/${BPN}-${PV}.tar.xz"
|
|
SRC_URI += "file://0001-Use-Os-to-compile-hb-subset-plan-layout.cc.patch"
|
|
SRC_URI[sha256sum] = "50f7d0a208367e606dbf6eecc5cfbecc01a47be6ee837ae7aff2787e24b09b45"
|
|
|
|
DEPENDS += "glib-2.0-native"
|
|
|
|
inherit meson pkgconfig lib_package gtk-doc gobject-introspection github-releases
|
|
|
|
GIR_MESON_ENABLE_FLAG = 'enabled'
|
|
GIR_MESON_DISABLE_FLAG = 'disabled'
|
|
GTKDOC_MESON_ENABLE_FLAG = 'enabled'
|
|
GTKDOC_MESON_DISABLE_FLAG = 'disabled'
|
|
|
|
PACKAGECONFIG ??= "cairo freetype glib icu"
|
|
PACKAGECONFIG[cairo] = "-Dcairo=enabled,-Dcairo=disabled,cairo"
|
|
PACKAGECONFIG[chafa] = "-Dchafa=enabled,-Dchafa=disabled,chafa"
|
|
PACKAGECONFIG[freetype] = "-Dfreetype=enabled,-Dfreetype=disabled,freetype"
|
|
PACKAGECONFIG[glib] = "-Dglib=enabled,-Dglib=disabled,glib-2.0"
|
|
PACKAGECONFIG[graphite] = "-Dgraphite2=enabled,-Dgraphite2=disabled,graphite2"
|
|
PACKAGECONFIG[icu] = "-Dicu=enabled,-Dicu=disabled,icu"
|
|
|
|
PACKAGES =+ "${PN}-icu ${PN}-icu-dev ${PN}-subset"
|
|
|
|
LEAD_SONAME = "libharfbuzz.so"
|
|
|
|
do_install:append() {
|
|
# If no tools are installed due to PACKAGECONFIG then this directory might
|
|
# still be installed, so remove it to stop packaging warnings.
|
|
[ ! -d ${D}${bindir} ] || rmdir --ignore-fail-on-non-empty ${D}${bindir}
|
|
}
|
|
|
|
FILES:${PN}-icu = "${libdir}/libharfbuzz-icu.so.*"
|
|
FILES:${PN}-icu-dev = "${libdir}/libharfbuzz-icu.la \
|
|
${libdir}/libharfbuzz-icu.so \
|
|
${libdir}/pkgconfig/harfbuzz-icu.pc \
|
|
"
|
|
FILES:${PN}-subset = "${libdir}/libharfbuzz-subset.so.*"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|