mirror of
git://git.yoctoproject.org/poky
synced 2026-10-14 00:37:30 +00:00
8d883040a6
(From OE-Core rev: 90e2bdc6bc07db35a53b2103646684f75081125e) Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
42 lines
1.6 KiB
BlitzBasic
42 lines
1.6 KiB
BlitzBasic
SUMMARY = "Framework for layout and rendering of internationalized text"
|
|
DESCRIPTION = "Pango is a library for laying out and rendering of text, \
|
|
with an emphasis on internationalization. Pango can be used anywhere \
|
|
that text layout is needed, though most of the work on Pango so far has \
|
|
been done in the context of the GTK+ widget toolkit. Pango forms the \
|
|
core of text and font handling for GTK+-2.x."
|
|
HOMEPAGE = "http://www.pango.org/"
|
|
BUGTRACKER = "http://bugzilla.gnome.org"
|
|
SECTION = "libs"
|
|
LICENSE = "LGPL-2.0-or-later"
|
|
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=3bf50002aefd002f49e7bb854063f7e7"
|
|
|
|
inherit gnomebase gi-docgen upstream-version-is-even gobject-introspection
|
|
|
|
UPSTREAM_CHECK_REGEX = "pango-(?P<pver>\d+\.(?!9\d+)\d+\.\d+)"
|
|
|
|
GIR_MESON_ENABLE_FLAG = "enabled"
|
|
GIR_MESON_DISABLE_FLAG = "disabled"
|
|
|
|
SRC_URI[archive.sha256sum] = "2606252bc25cd8d24e1b7f7e92c3a272b37acd6734347b73b47a482834ba2491"
|
|
|
|
DEPENDS = "glib-2.0 glib-2.0-native fontconfig freetype virtual/libiconv cairo harfbuzz fribidi"
|
|
DEPENDS += "${@' python3-docutils-native' if d.getVar('GIDOCGEN_ENABLED') == 'True' else ''}"
|
|
|
|
PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'x11', d)}"
|
|
|
|
PACKAGECONFIG[x11] = ",,virtual/libx11 libxft"
|
|
PACKAGECONFIG[thai] = "-Dlibthai=enabled,-Dlibthai=disabled,libthai"
|
|
|
|
GIR_MESON_OPTION = 'introspection'
|
|
GIDOCGEN_MESON_OPTION = 'documentation'
|
|
|
|
LEAD_SONAME = "libpango-1.0*"
|
|
|
|
FILES:${PN} = "${bindir}/* ${libdir}/libpango*${SOLIBS}"
|
|
|
|
RPROVIDES:${PN} += "pango-modules pango-module-indic-lang \
|
|
pango-module-basic-fc pango-module-arabic-lang"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|