mirror of
git://git.yoctoproject.org/poky
synced 2026-09-08 00:06:57 +00:00
085adb197b
Add a ptest for tar. - It is taking around 3m to execute with kvm, so added it to PTEST_SLOW. - It contains 244 cases. - Below is parts of the run log: START: ptest-runner 2023-09-26T08:37 BEGIN: /usr/lib/tar/ptest ## ------------------------ ## ## GNU tar 1.35 test suite. ## ## ------------------------ ## PASS: tar version PASS: decompressing from stdin ... 200 tests were successful. 44 tests were skipped. DURATION: 190 END: /usr/lib/tar/ptest 2023-09-26T08:40 STOP: ptest-runner TOTAL: 1 FAIL: 0 (From OE-Core rev: 12eed1e6c701759321541d2c04eeca3db3c99247) Signed-off-by: Qiu Tingting <qiutt@fujitsu.com> Signed-off-by: Yan Xinkuan <yanxk.fnst@fujitsu.com> Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
46 lines
1.6 KiB
BlitzBasic
46 lines
1.6 KiB
BlitzBasic
inherit features_check
|
|
REQUIRED_DISTRO_FEATURES = "ptest"
|
|
|
|
require core-image-minimal.bb
|
|
require conf/distro/include/ptest-packagelists.inc
|
|
|
|
DESCRIPTION += "Also including the ${MCNAME} ptest package."
|
|
SUMMARY ?= "${MCNAME} ptest image."
|
|
HOMEPAGE = "https://www.yoctoproject.org/"
|
|
|
|
PTESTS = "${PTESTS_SLOW} ${PTESTS_FAST}"
|
|
|
|
IMAGE_INSTALL:append = " ${MCNAME}-ptest openssh"
|
|
|
|
BBCLASSEXTEND = "${@' '.join(['mcextend:'+x for x in d.getVar('PTESTS').split()])}"
|
|
|
|
# The image can sufficiently large (~1.8GB) that we need to be careful that it fits in a live
|
|
# image (which has a 4GB limit), so nullify the overhead factor (1.3x out of the
|
|
# box) and explicitly add up to 1500MB.
|
|
# strace-ptest in particular needs more than 500MB
|
|
IMAGE_OVERHEAD_FACTOR = "1.0"
|
|
IMAGE_ROOTFS_EXTRA_SPACE = "324288"
|
|
IMAGE_ROOTFS_EXTRA_SPACE:virtclass-mcextend-mdadm = "1524288"
|
|
IMAGE_ROOTFS_EXTRA_SPACE:virtclass-mcextend-strace = "1024288"
|
|
IMAGE_ROOTFS_EXTRA_SPACE:virtclass-mcextend-lttng-tools = "1524288"
|
|
|
|
# tar-ptest in particular needs more space
|
|
IMAGE_ROOTFS_EXTRA_SPACE:virtclass-mcextend-tar = "1524288"
|
|
|
|
# ptests need more memory than standard to avoid the OOM killer
|
|
QB_MEM = "-m 1024"
|
|
QB_MEM:virtclass-mcextend-lttng-tools = "-m 4096"
|
|
QB_MEM:virtclass-mcextend-python3 = "-m 2048"
|
|
QB_MEM:virtclass-mcextend-python3-cryptography = "-m 4096"
|
|
|
|
TEST_SUITES = "ping ssh parselogs ptest"
|
|
|
|
# Sadly at the moment the full set of ptests is not robust enough and sporadically fails in random places
|
|
PTEST_EXPECT_FAILURE = "1"
|
|
|
|
python () {
|
|
if not d.getVar("MCNAME"):
|
|
raise bb.parse.SkipRecipe("No class extension set")
|
|
}
|
|
|