mirror of
git://git.yoctoproject.org/poky
synced 2026-10-02 18:48:47 +00:00
31a7824665
Backported from master with two differences: 1. Move exit in do_make_icudata_class-target after big endian patch application (not required for master since new upstream icu includes the patch) 2. In do_install_append_class-target test for existence of .dat input file before calling icupkg icu data generation was found to be racy, and causig AB failures; making it serial and leaving it on is not an option as it regresses to several minutes. The specific bug is that rules.mk has: LD_LIBRARY_PATH=../lib:../stubdata:../tools/ctestfw:$LD_LIBRARY_PATH ../bin/gencnval -s . -d ./out/build/icudt66l mappings/convrtrs.txt which creates a file and numerous rules like LD_LIBRARY_PATH=../lib:../stubdata:../tools/ctestfw:$LD_LIBRARY_PATH ../bin/genrb -s ./misc -d ./out/build/icudt67l -i ./out/build/icudt67l -k -q numberingSystems.txt which quietly read it. There is no prerequisite for the former to complete first. The race is extra complicated to fix as rules.mk is itself generated through a custom in-tree python tool. (From OE-Core rev: df4bfb154e7fce9645f5738aa04b3eb3ef5093fe) Signed-off-by: Alexander Kanavin <alex.kanavin@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> (cherry picked from commit df89e8d1136fd406ba35ae573e2cb0cfc88c6aad) Signed-off-by: Steve Sakoman <steve@sakoman.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
72 lines
2.4 KiB
BlitzBasic
72 lines
2.4 KiB
BlitzBasic
require icu.inc
|
|
|
|
LIC_FILES_CHKSUM = "file://../LICENSE;md5=a3808a5b70071b07f87ff2205e4d75a0"
|
|
|
|
def icu_download_version(d):
|
|
pvsplit = d.getVar('PV').split('.')
|
|
return pvsplit[0] + "_" + pvsplit[1]
|
|
|
|
def icu_download_folder(d):
|
|
pvsplit = d.getVar('PV').split('.')
|
|
return pvsplit[0] + "-" + pvsplit[1]
|
|
|
|
ICU_PV = "${@icu_download_version(d)}"
|
|
ICU_FOLDER = "${@icu_download_folder(d)}"
|
|
|
|
# http://errors.yoctoproject.org/Errors/Details/20486/
|
|
ARM_INSTRUCTION_SET_armv4 = "arm"
|
|
ARM_INSTRUCTION_SET_armv5 = "arm"
|
|
|
|
BASE_SRC_URI = "https://github.com/unicode-org/icu/releases/download/release-${ICU_FOLDER}/icu4c-${ICU_PV}-src.tgz"
|
|
DATA_SRC_URI = "https://github.com/unicode-org/icu/releases/download/release-${ICU_FOLDER}/icu4c-${ICU_PV}-data.zip"
|
|
SRC_URI = "${BASE_SRC_URI};name=code \
|
|
${DATA_SRC_URI};name=data \
|
|
file://filter.json \
|
|
file://icu-pkgdata-large-cmd.patch \
|
|
file://fix-install-manx.patch \
|
|
file://0001-Fix-big-endian-build.patch;apply=no \
|
|
file://0001-icu-Added-armeb-support.patch \
|
|
file://CVE-2020-10531.patch \
|
|
"
|
|
|
|
SRC_URI_append_class-target = "\
|
|
file://0001-Disable-LDFLAGSICUDT-for-Linux.patch \
|
|
"
|
|
SRC_URI[code.sha256sum] = "52a3f2209ab95559c1cf0a14f24338001f389615bf00e2585ef3dbc43ecf0a2e"
|
|
SRC_URI[data.sha256sum] = "8be647f738891d2beb79d48f99077b3499948430eae6f1be112553b15ab0243e"
|
|
|
|
UPSTREAM_CHECK_REGEX = "icu4c-(?P<pver>\d+(_\d+)+)-src"
|
|
UPSTREAM_CHECK_URI = "https://github.com/unicode-org/icu/releases"
|
|
|
|
EXTRA_OECONF_append_libc-musl = " ac_cv_func_strtod_l=no"
|
|
|
|
PACKAGECONFIG ?= ""
|
|
PACKAGECONFIG[make-icudata] = ",,,"
|
|
|
|
do_make_icudata_class-target () {
|
|
cd ${S}
|
|
rm -rf data
|
|
cp -a ${WORKDIR}/data .
|
|
patch -p1 < ${WORKDIR}/0001-Fix-big-endian-build.patch
|
|
${@bb.utils.contains('PACKAGECONFIG', 'make-icudata', '', 'exit 0', d)}
|
|
AR='${BUILD_AR}' \
|
|
CC='${BUILD_CC}' \
|
|
CPP='${BUILD_CPP}' \
|
|
CXX='${BUILD_CXX}' \
|
|
RANLIB='${BUILD_RANLIB}' \
|
|
CFLAGS='${BUILD_CFLAGS}' \
|
|
CPPFLAGS='${BUILD_CPPFLAGS}' \
|
|
CXXFLAGS='${BUILD_CXXFLAGS}' \
|
|
LDFLAGS='${BUILD_LDFLAGS}' \
|
|
ICU_DATA_FILTER_FILE=${WORKDIR}/filter.json \
|
|
./runConfigureICU Linux --with-data-packaging=archive
|
|
oe_runmake
|
|
install -Dm644 ${S}/data/out/icudt${ICU_MAJOR_VER}l.dat ${S}/data/in/icudt${ICU_MAJOR_VER}l.dat
|
|
}
|
|
|
|
do_make_icudata() {
|
|
:
|
|
}
|
|
|
|
addtask make_icudata before do_configure after do_patch
|