mirror of
git://git.yoctoproject.org/poky
synced 2026-10-02 18:18:12 +00:00
3a6f0b66a5
Instead of setting S to a directory inside the tarball and B to another directory inside the tarball, use the default value of S and set AUTOTOOLS_SCRIPT_PATH to the right path to find configure. Update the patches so they still apply, and clean up the recipe slightly. Because something is not quite right regarding quilt and patching, add a PR bump to the recipes to ensure that a clean work directory is used: for some reason rebuilds will rarely fail to patch correctly. (From OE-Core rev: dcbef72b8344c22617d65ea1e9f0fa7ad9a742bd) Signed-off-by: Ross Burton <ross.burton@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
112 lines
3.5 KiB
BlitzBasic
112 lines
3.5 KiB
BlitzBasic
# Version 5 of the Berkeley DB from Sleepycat
|
|
#
|
|
# At present this package only installs the DB code
|
|
# itself (shared libraries, .a in the dev package),
|
|
# documentation and headers.
|
|
#
|
|
# The headers have the same names as those as v3
|
|
# of the DB, only one version can be used *for dev*
|
|
# at once - DB3 and DB5 can both be installed on the
|
|
# same system at the same time if really necessary.
|
|
SECTION = "libs"
|
|
SUMMARY = "Berkeley Database v5"
|
|
HOMEPAGE = "http://www.oracle.com/technetwork/database/database-technologies/berkeleydb/overview/index.html"
|
|
LICENSE = "Sleepycat"
|
|
VIRTUAL_NAME ?= "virtual/db"
|
|
RCONFLICTS_${PN} = "db3"
|
|
|
|
PR = "r1"
|
|
|
|
SRC_URI = "http://download.oracle.com/berkeley-db/db-${PV}.tar.gz"
|
|
SRC_URI += "file://arm-thumb-mutex_db5.patch \
|
|
file://fix-parallel-build.patch \
|
|
"
|
|
|
|
SRC_URI[md5sum] = "b99454564d5b4479750567031d66fe24"
|
|
SRC_URI[sha256sum] = "e0a992d740709892e81f9d93f06daf305cf73fb81b545afe72478043172c3628"
|
|
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=ed1158e31437f4f87cdd4ab2b8613955"
|
|
|
|
inherit autotools
|
|
|
|
# Put virtual/db in any appropriate provider of a
|
|
# relational database, use it as a dependency in
|
|
# place of a specific db and use:
|
|
#
|
|
# PREFERRED_PROVIDER_virtual/db
|
|
#
|
|
# to select the correct db in the build (distro) .conf
|
|
PROVIDES += "${VIRTUAL_NAME}"
|
|
|
|
# The executables go in a separate package - typically there
|
|
# is no need to install these unless doing real database
|
|
# management on the system.
|
|
inherit lib_package
|
|
|
|
PACKAGES =+ "${PN}-cxx"
|
|
FILES_${PN}-cxx = "${libdir}/*cxx*so"
|
|
|
|
|
|
# The dev package has the .so link (as in db3) and the .a's -
|
|
# it is therefore incompatible (cannot be installed at the
|
|
# same time) as the db3 package
|
|
# sort out the .so since they do version prior to the .so
|
|
SOLIBS = "-5*.so"
|
|
FILES_SOLIBSDEV = "${libdir}/libdb.so ${libdir}/libdb_cxx.so"
|
|
|
|
#configuration - set in local.conf to override
|
|
# All the --disable-* options replace --enable-smallbuild, which breaks a bunch of stuff (eg. postfix)
|
|
DB5_CONFIG ?= "--enable-o_direct --disable-cryptography --disable-queue --disable-replication --disable-verify --disable-compat185 --disable-sql"
|
|
|
|
EXTRA_OECONF = "${DB5_CONFIG} --enable-shared --enable-cxx --with-sysroot"
|
|
|
|
# Override the MUTEX setting here, the POSIX library is
|
|
# the default - "POSIX/pthreads/library".
|
|
# Don't ignore the nice SWP instruction on the ARM:
|
|
# These enable the ARM assembler mutex code, this won't
|
|
# work with thumb compilation...
|
|
ARM_MUTEX = "--with-mutex=ARM/gcc-assembly"
|
|
MUTEX = ""
|
|
MUTEX_arm = "${ARM_MUTEX}"
|
|
MUTEX_armeb = "${ARM_MUTEX}"
|
|
EXTRA_OECONF += "${MUTEX} STRIP=true"
|
|
|
|
AUTOTOOLS_SCRIPT_PATH = "${S}/dist"
|
|
|
|
# Cancel the site stuff - it's set for db3 and destroys the
|
|
# configure.
|
|
CONFIG_SITE = ""
|
|
do_configure() {
|
|
cd ${B}
|
|
gnu-configize --force ${AUTOTOOLS_SCRIPT_PATH}
|
|
oe_runconf
|
|
}
|
|
|
|
do_compile_prepend() {
|
|
# Stop libtool adding RPATHs
|
|
sed -i -e 's|hardcode_into_libs=yes|hardcode_into_libs=no|' ${B}/libtool
|
|
}
|
|
|
|
do_install_append() {
|
|
mkdir -p ${D}/${includedir}/db51
|
|
mv ${D}/${includedir}/db.h ${D}/${includedir}/db51/.
|
|
mv ${D}/${includedir}/db_cxx.h ${D}/${includedir}/db51/.
|
|
ln -s db51/db.h ${D}/${includedir}/db.h
|
|
ln -s db51/db_cxx.h ${D}/${includedir}/db_cxx.h
|
|
|
|
# The docs end up in /usr/docs - not right.
|
|
if test -d "${D}/${prefix}/docs"
|
|
then
|
|
mkdir -p "${D}/${datadir}"
|
|
test ! -d "${D}/${docdir}" || rm -rf "${D}/${docdir}"
|
|
mv "${D}/${prefix}/docs" "${D}/${docdir}"
|
|
fi
|
|
|
|
chown -R root:root ${D}
|
|
}
|
|
|
|
INSANE_SKIP_${PN} = "dev-so"
|
|
INSANE_SKIP_${PN}-cxx = "dev-so"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|