mirror of
git://git.yoctoproject.org/poky
synced 2026-09-08 03:54:15 +00:00
d4ad8f7119
Drop the 2 patches since the functionality is upstream now. Also sync PACKAGECONFIG with grub 2.00 recipe. The debugedit problem for 64 bit machines in do_package is still present, though: ERROR: debugedit failed with exit code 256 (cmd was '/build/linaro/build/build/tmp-eglibc/sysroots/x86_64-linux/usr/lib/rpm/bin/debugedit' -b '/build/linaro/build/build/tmp-eglibc/work/aarch64-oe-linux' -d '/usr/src/debug' -i -l '/build/linaro/build/build/tmp-eglibc/work/aarch64-oe-linux/grub/2.00+AUTOINC+0776112c53-r0/debugsources.list' '/build/linaro/build/build/tmp-eglibc/work/aarch64-oe-linux/grub/2.00+AUTOINC+0776112c53-r0/package/usr/lib/grub/arm64-efi/cpio_be.module'): /build/linaro/build/build/tmp-eglibc/sysroots/x86_64-linux/usr/lib/rpm/bin/debugedit: /build/linaro/build/build/tmp-eglibc/work/aarch64-oe-linux/grub/2.00+AUTOINC+0776112c53-r0/package/usr/lib/grub/arm64-efi/cpio_be.module: Unhandled relocation 258 in .debug_info section ERROR: Function failed: split_and_strip_files ERROR: Logfile of failure stored in: /build/linaro/build/build/tmp-eglibc/work/aarch64-oe-linux/grub/2.00+AUTOINC+0776112c53-r0/temp/log.do_package.29234 ERROR: Task 10 (/build/linaro/build/openembedded-core/meta/recipes-bsp/grub/grub_git.bb, do_package) failed with exit code '1' (From OE-Core rev: cd29ff3927a6deae5e808525bd56acf7b4b0b60c) Signed-off-by: Koen Kooi <koen.kooi@linaro.org> Signed-off-by: Saul Wold <sgw@linux.intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
61 lines
1.8 KiB
BlitzBasic
61 lines
1.8 KiB
BlitzBasic
SUMMARY = "GRUB2 is the next-generation GRand Unified Bootloader"
|
|
|
|
DESCRIPTION = "GRUB2 is the next generaion of a GPLed bootloader \
|
|
intended to unify bootloading across x86 operating systems. In \
|
|
addition to loading the Linux kernel, it implements the Multiboot \
|
|
standard, which allows for flexible loading of multiple boot images."
|
|
|
|
HOMEPAGE = "http://www.gnu.org/software/grub/"
|
|
SECTION = "bootloaders"
|
|
|
|
LICENSE = "GPLv3"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504"
|
|
|
|
DEPENDS = "autogen-native flex-native bison-native xz freetype"
|
|
|
|
DEFAULT_PREFERENCE = "-1"
|
|
DEFAULT_PREFERENCE_arm = "1"
|
|
|
|
PV = "2.00+${SRCPV}"
|
|
SRCREV = "0776112c5311196889a15058a3b1be4c81ba5e05"
|
|
SRC_URI = "git://git.savannah.gnu.org/grub.git \
|
|
file://40_custom \
|
|
"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
COMPATIBLE_HOST = '(x86_64.*|i.86.*|arm.*|aarch64.*)-(linux.*|freebsd.*)'
|
|
|
|
inherit autotools
|
|
inherit gettext
|
|
|
|
PACKAGECONFIG ??= ""
|
|
PACKAGECONFIG[grub-mount] = "--enable-grub-mount,--disable-grub-mount,fuse"
|
|
PACKAGECONFIG[device-mapper] = "--enable-device-mapper,--disable-device-mapper,lvm2"
|
|
|
|
# configure.ac has code to set this automagically from the target tuple
|
|
# but the OE freeform one (core2-foo-bar-linux) don't work with that.
|
|
|
|
GRUBPLATFORM_arm = "uboot"
|
|
GRUBPLATFORM_aarch64 = "efi"
|
|
GRUBPLATFORM ??= "pc"
|
|
|
|
EXTRA_OECONF = "--with-platform=${GRUBPLATFORM} --disable-grub-mkfont --program-prefix="" \
|
|
--enable-liblzma=no --enable-device-mapper=no --enable-libzfs=no"
|
|
|
|
do_configure_prepend() {
|
|
( cd ${S}
|
|
${S}/autogen.sh )
|
|
}
|
|
|
|
do_install_append () {
|
|
install -d ${D}${sysconfdir}/grub.d
|
|
install -m 0755 ${WORKDIR}/40_custom ${D}${sysconfdir}/grub.d/40_custom
|
|
}
|
|
|
|
RDEPENDS_${PN} = "diffutils freetype"
|
|
FILES_${PN}-dbg += "${libdir}/${BPN}/*/.debug"
|
|
|
|
INSANE_SKIP_${PN} = "arch"
|
|
INSANE_SKIP_${PN}-dbg = "arch"
|