mirror of
git://git.yoctoproject.org/poky
synced 2026-05-18 22:16:55 +00:00
4f3a8ee65b
Bumping the version of -dev ot 5.16. We also pickup two new
dependencies to support kernel dtschema validation. This
requirement was introduced by kernel commit:
commit 53182e81f47d4ea0c727c49ad23cb782173ab849
Author: Rob Herring <robh@kernel.org>
Date: Mon Sep 13 09:51:46 2021 -0500
kbuild: Enable DT schema checks for %.dtb targets
It is possible to build a single dtb, but not with DT schema validation
enabled. Enable the schema validation to run for %.dtb and %.dtbo
targets. Anyone building a dtb for a specific platform *should* pay
attention to schema warnings.
This could be supported with a separate %.dt.yaml target instead.
However, the .dt.yaml format is considered an intermediate format and
could possibly go away at some point if schema checking is integrated
into dtc. Also, the plan is to enable the schema checks by default once
platforms are free of warnings, and this is a move in that direction.
Cc: Dmitry Baryshkov <dmitry.baryshkov@linaro.org>
Cc: Tom Rini <trini@konsulko.com>
Cc: Masahiro Yamada <masahiroy@kernel.org>
Cc: linux-kbuild@vger.kernel.org
Signed-off-by: Rob Herring <robh@kernel.org>
Acked-by: Masahiro Yamada <masahiroy@kernel.org>
Link: https://lore.kernel.org/r/20210913145146.766080-1-robh@kernel.org
(From OE-Core rev: 37fb1592eb8bcc4a8bbfc3f4b1dc6373733827f0)
Signed-off-by: Bruce Ashfield <bruce.ashfield@gmail.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
60 lines
2.9 KiB
BlitzBasic
60 lines
2.9 KiB
BlitzBasic
# This recipe tracks the linux-yocto-dev repository as its upstream source.
|
|
# Since this tree is frequently updated, and periodically rebuilt, AUTOREV is
|
|
# used to track its contents.
|
|
#
|
|
# This recipe is just like other linux-yocto variants, with the only difference
|
|
# being that to avoid network access during initial parsing, static SRCREVs are
|
|
# provided and overridden if the preferred kernel provider is linux-yocto-dev.
|
|
#
|
|
# To enable this recipe, set PREFERRED_PROVIDER_virtual/kernel = "linux-yocto-dev"
|
|
|
|
inherit kernel
|
|
require recipes-kernel/linux/linux-yocto.inc
|
|
# for ncurses tests
|
|
inherit pkgconfig
|
|
|
|
# provide this .inc to set specific revisions
|
|
include recipes-kernel/linux/linux-yocto-dev-revisions.inc
|
|
|
|
KBRANCH = "standard/base"
|
|
KMETA = "kernel-meta"
|
|
|
|
SRC_URI = "git://git.yoctoproject.org/linux-yocto-dev.git;branch=${KBRANCH};name=machine \
|
|
git://git.yoctoproject.org/yocto-kernel-cache;type=kmeta;name=meta;branch=master;destsuffix=${KMETA}"
|
|
|
|
# Set default SRCREVs. Both the machine and meta SRCREVs are statically set
|
|
# to the korg v3.7 tag, and hence prevent network access during parsing. If
|
|
# linux-yocto-dev is the preferred provider, they will be overridden to
|
|
# AUTOREV in following anonymous python routine and resolved when the
|
|
# variables are finalized.
|
|
SRCREV_machine ?= '${@oe.utils.conditional("PREFERRED_PROVIDER_virtual/kernel", "linux-yocto-dev", "${AUTOREV}", "29594404d7fe73cd80eaa4ee8c43dcc53970c60e", d)}'
|
|
SRCREV_meta ?= '${@oe.utils.conditional("PREFERRED_PROVIDER_virtual/kernel", "linux-yocto-dev", "${AUTOREV}", "29594404d7fe73cd80eaa4ee8c43dcc53970c60e", d)}'
|
|
|
|
LINUX_VERSION ?= "5.16+"
|
|
LINUX_VERSION_EXTENSION ?= "-yoctodev-${LINUX_KERNEL_TYPE}"
|
|
PV = "${LINUX_VERSION}+git${SRCPV}"
|
|
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=6bc538ed5bd9a7fc9398086aedcd7e46"
|
|
|
|
DEPENDS += "${@bb.utils.contains('ARCH', 'x86', 'elfutils-native', '', d)}"
|
|
DEPENDS += "openssl-native util-linux-native"
|
|
DEPENDS += "gmp-native libmpc-native"
|
|
# yaml and dtschema are required for 5.16+ device tree validation
|
|
DEPENDS += "libyaml-native python3-dtschema-native"
|
|
|
|
COMPATIBLE_MACHINE = "(qemuarm|qemux86|qemuppc|qemumips|qemumips64|qemux86-64|qemuriscv64)"
|
|
|
|
KERNEL_DEVICETREE:qemuarmv5 = "versatile-pb.dtb"
|
|
|
|
# Functionality flags
|
|
KERNEL_EXTRA_FEATURES ?= "features/netfilter/netfilter.scc features/taskstats/taskstats.scc"
|
|
KERNEL_FEATURES:append = " ${KERNEL_EXTRA_FEATURES}"
|
|
KERNEL_FEATURES:append:qemuall=" cfg/virtio.scc features/drm-bochs/drm-bochs.scc"
|
|
KERNEL_FEATURES:append:qemux86=" cfg/sound.scc cfg/paravirt_kvm.scc"
|
|
KERNEL_FEATURES:append:qemux86-64=" cfg/sound.scc cfg/paravirt_kvm.scc"
|
|
KERNEL_FEATURES:append = " ${@bb.utils.contains("TUNE_FEATURES", "mx32", " cfg/x32.scc", "", d)}"
|
|
KERNEL_FEATURES:append = " ${@bb.utils.contains("DISTRO_FEATURES", "ptest", " features/scsi/scsi-debug.scc", "", d)}"
|
|
KERNEL_FEATURES:append = " ${@bb.utils.contains("DISTRO_FEATURES", "ptest", " features/gpio/mockup.scc", "", d)}"
|
|
|
|
KERNEL_VERSION_SANITY_SKIP = "1"
|