mirror of
git://git.yoctoproject.org/poky
synced 2026-10-02 13:56:03 +00:00
537ffe0d95
Convert to cmake, drop all the unneeded cruft from the recipe. License-Update: additional contributors (From OE-Core rev: adba510022781f139014d6174e46954c1f4774c0) Signed-off-by: Alexander Kanavin <alex.kanavin@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
56 lines
1.7 KiB
BlitzBasic
56 lines
1.7 KiB
BlitzBasic
SUMMARY = "Simon Tatham's Portable Puzzle Collection"
|
|
DESCRIPTION = "Collection of small computer programs which implement one-player puzzle games."
|
|
HOMEPAGE = "http://www.chiark.greenend.org.uk/~sgtatham/puzzles/"
|
|
LICENSE = "MIT"
|
|
LIC_FILES_CHKSUM = "file://LICENCE;md5=93c2525113e094a4a744cf14d4de07e2"
|
|
|
|
# gtk support includes a bunch of x11 headers
|
|
REQUIRED_DISTRO_FEATURES = "x11"
|
|
|
|
SRC_URI = "git://git.tartarus.org/simon/puzzles.git \
|
|
file://fix-compiling-failure-with-option-g-O.patch \
|
|
file://0001-palisade-Fix-warnings-with-clang-on-arm.patch \
|
|
file://0001-pattern.c-Change-string-lenght-parameter-to-be-size_.patch \
|
|
file://fix-ki-uninitialized.patch \
|
|
file://0001-malloc-Check-for-excessive-values-to-malloc.patch \
|
|
file://0001-map-Fix-stringop-overflow-warning.patch \
|
|
"
|
|
|
|
UPSTREAM_CHECK_COMMITS = "1"
|
|
SRCREV = "c0da615a933a6676e2c6b957368067ca1bc10abd"
|
|
PE = "2"
|
|
PV = "0.0+git${SRCPV}"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
inherit cmake features_check pkgconfig
|
|
|
|
DEPENDS += "gtk+3"
|
|
|
|
do_install_append () {
|
|
# net conflicts with Samba, so rename it
|
|
mv ${D}${bindir}/net ${D}${bindir}/puzzles-net
|
|
|
|
# Create desktop shortcuts
|
|
install -d ${D}/${datadir}/applications/
|
|
cd ${D}/${prefix}/bin
|
|
for prog in *; do
|
|
if [ -x $prog ]; then
|
|
# Convert prog to Title Case
|
|
title=$(echo $prog | sed 's/puzzles-//' | sed 's/\(^\| \)./\U&/g')
|
|
echo "making ${D}/${datadir}/applications/$prog.desktop"
|
|
cat <<STOP > ${D}/${datadir}/applications/$prog.desktop
|
|
[Desktop Entry]
|
|
Name=$title
|
|
Exec=${bindir}/$prog
|
|
Icon=applications-games
|
|
Terminal=false
|
|
Type=Application
|
|
Categories=Game;
|
|
StartupNotify=true
|
|
STOP
|
|
fi
|
|
done
|
|
}
|
|
|