mirror of
git://git.yoctoproject.org/poky
synced 2026-10-02 16:42:04 +00:00
60f1d08fa6
Libarchive 3.6.2 is a bugfix and security release. Important security fixes: NULL pointer dereference vulnerability in archive_write.c (#1754, #1759, CVE-2022-36227) Important bug fixes: include ZSTD in Windows builds (#1688) SSL fixes on Windows (#1714, #1723, #1724) rar5 reader: fix possible garbled output with bsdtar -O (#1745) mtree reader: support reading mtree files with tabs (#1783) various small fixes for issues found by CodeQL Use --without-iconv as otherwise autotools write a bogus iconv dependency into .pc file. (From OE-Core rev: 41e1b4c29e45a9022eea8f89dfb09b6eb2eae60b) Signed-off-by: Alexander Kanavin <alex@linutronix.de> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> (cherry picked from commit edce1bce81fe2f47fb2c5e2b94ebda73f95cbaea) Signed-off-by: Steve Sakoman <steve@sakoman.com> (cherry picked from commit 93b972845a28b62ea01ee0f4a1e043bd58fc0892) Signed-off-by: Steve Sakoman <steve@sakoman.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
68 lines
2.4 KiB
BlitzBasic
68 lines
2.4 KiB
BlitzBasic
SUMMARY = "Support for reading various archive formats"
|
|
DESCRIPTION = "C library and command-line tools for reading and writing tar, cpio, zip, ISO, and other archive formats"
|
|
HOMEPAGE = "http://www.libarchive.org/"
|
|
SECTION = "devel"
|
|
LICENSE = "BSD-2-Clause"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=d499814247adaee08d88080841cb5665"
|
|
|
|
DEPENDS = "e2fsprogs-native"
|
|
|
|
PACKAGECONFIG ?= "zlib bz2 xz lzo zstd"
|
|
|
|
PACKAGECONFIG:append:class-target = "\
|
|
${@bb.utils.filter('DISTRO_FEATURES', 'acl xattr', d)} \
|
|
"
|
|
|
|
DEPENDS_BZIP2 = "bzip2-replacement-native"
|
|
DEPENDS_BZIP2:class-target = "bzip2"
|
|
|
|
PACKAGECONFIG[acl] = "--enable-acl,--disable-acl,acl,"
|
|
PACKAGECONFIG[xattr] = "--enable-xattr,--disable-xattr,attr,"
|
|
PACKAGECONFIG[zlib] = "--with-zlib,--without-zlib,zlib,"
|
|
PACKAGECONFIG[bz2] = "--with-bz2lib,--without-bz2lib,${DEPENDS_BZIP2},"
|
|
PACKAGECONFIG[xz] = "--with-lzma,--without-lzma,xz,"
|
|
PACKAGECONFIG[openssl] = "--with-openssl,--without-openssl,openssl,"
|
|
PACKAGECONFIG[libxml2] = "--with-xml2,--without-xml2,libxml2,"
|
|
PACKAGECONFIG[expat] = "--with-expat,--without-expat,expat,"
|
|
PACKAGECONFIG[lzo] = "--with-lzo2,--without-lzo2,lzo,"
|
|
PACKAGECONFIG[nettle] = "--with-nettle,--without-nettle,nettle,"
|
|
PACKAGECONFIG[lz4] = "--with-lz4,--without-lz4,lz4,"
|
|
PACKAGECONFIG[mbedtls] = "--with-mbedtls,--without-mbedtls,mbedtls,"
|
|
PACKAGECONFIG[zstd] = "--with-zstd,--without-zstd,zstd,"
|
|
|
|
EXTRA_OECONF += "--enable-largefile --without-iconv"
|
|
|
|
SRC_URI = "http://libarchive.org/downloads/libarchive-${PV}.tar.gz"
|
|
UPSTREAM_CHECK_URI = "http://libarchive.org/"
|
|
|
|
SRC_URI[sha256sum] = "ba6d02f15ba04aba9c23fd5f236bb234eab9d5209e95d1c4df85c44d5f19b9b3"
|
|
|
|
inherit autotools update-alternatives pkgconfig
|
|
|
|
CPPFLAGS += "-I${WORKDIR}/extra-includes"
|
|
|
|
do_configure[cleandirs] += "${WORKDIR}/extra-includes"
|
|
do_configure:prepend() {
|
|
# We just need the headers for some type constants, so no need to
|
|
# build all of e2fsprogs for the target
|
|
cp -R ${STAGING_INCDIR_NATIVE}/ext2fs ${WORKDIR}/extra-includes/
|
|
}
|
|
|
|
ALTERNATIVE_PRIORITY = "80"
|
|
|
|
PACKAGES =+ "bsdtar"
|
|
FILES:bsdtar = "${bindir}/bsdtar"
|
|
|
|
ALTERNATIVE:bsdtar = "tar"
|
|
ALTERNATIVE_LINK_NAME[tar] = "${base_bindir}/tar"
|
|
ALTERNATIVE_TARGET[tar] = "${bindir}/bsdtar"
|
|
|
|
PACKAGES =+ "bsdcpio"
|
|
FILES:bsdcpio = "${bindir}/bsdcpio"
|
|
|
|
ALTERNATIVE:bsdcpio = "cpio"
|
|
ALTERNATIVE_LINK_NAME[cpio] = "${base_bindir}/cpio"
|
|
ALTERNATIVE_TARGET[cpio] = "${bindir}/bsdcpio"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|