mirror of
git://git.yoctoproject.org/poky
synced 2026-09-17 00:34:20 +00:00
6834c083d6
There should be only one dev and dbg package. (From OE-Core rev: eb972e9b4b4210fa1c35fc0fae0ada27264b2e66) Signed-off-by: Robert Yang <liezhi.yang@windriver.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
51 lines
1.8 KiB
BlitzBasic
51 lines
1.8 KiB
BlitzBasic
SUMMARY = "Command line tool and library for client-side URL transfers"
|
|
HOMEPAGE = "http://curl.haxx.se/"
|
|
BUGTRACKER = "http://curl.haxx.se/mail/list.cgi?list=curl-tracker"
|
|
SECTION = "console/network"
|
|
LICENSE = "MIT"
|
|
LIC_FILES_CHKSUM = "file://COPYING;beginline=7;md5=3a34942f4ae3fbf1a303160714e664ac"
|
|
|
|
SRC_URI = "http://curl.haxx.se/download/curl-${PV}.tar.bz2 \
|
|
file://pkgconfig_fix.patch \
|
|
"
|
|
|
|
# curl likes to set -g0 in CFLAGS, so we stop it
|
|
# from mucking around with debug options
|
|
#
|
|
SRC_URI += " file://configure_ac.patch"
|
|
|
|
SRC_URI[md5sum] = "87e36f88b7a0f9683fa56f1334562c3a"
|
|
SRC_URI[sha256sum] = "9f8b546bdc5c57d959151acae7ce6610fe929d82b8d0fc5b25a3a2296e5f8bea"
|
|
|
|
inherit autotools pkgconfig binconfig multilib_header
|
|
|
|
PACKAGECONFIG ??= "${@bb.utils.contains("DISTRO_FEATURES", "ipv6", "ipv6", "", d)} gnutls zlib"
|
|
PACKAGECONFIG_class-native = "ipv6 ssl zlib"
|
|
PACKAGECONFIG_class-nativesdk = "ipv6 ssl zlib"
|
|
|
|
PACKAGECONFIG[ipv6] = "--enable-ipv6,--disable-ipv6,"
|
|
PACKAGECONFIG[ssl] = "--with-ssl --with-random=/dev/urandom,--without-ssl,openssl"
|
|
PACKAGECONFIG[gnutls] = "--with-gnutls,--without-gnutls,gnutls"
|
|
PACKAGECONFIG[zlib] = "--with-zlib=${STAGING_LIBDIR}/../,--without-zlib,zlib"
|
|
PACKAGECONFIG[rtmpdump] = "--with-librtmp,--without-librtmp,rtmpdump"
|
|
PACKAGECONFIG[libssh2] = "--with-libssh2,--without-libssh2,libssh2"
|
|
PACKAGECONFIG[smb] = "--enable-smb,--disable-smb,"
|
|
|
|
EXTRA_OECONF = "--without-libidn \
|
|
--enable-crypto-auth \
|
|
--disable-ldap \
|
|
--disable-ldaps \
|
|
--with-ca-bundle=${sysconfdir}/ssl/certs/ca-certificates.crt \
|
|
"
|
|
|
|
do_install_append() {
|
|
oe_multilib_header curl/curlbuild.h
|
|
}
|
|
|
|
PACKAGES =+ "lib${BPN}"
|
|
|
|
FILES_lib${BPN} = "${libdir}/lib*.so.*"
|
|
RRECOMMENDS_lib${BPN} += "ca-certificates"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|