mirror of
git://git.yoctoproject.org/poky
synced 2026-10-02 16:20:14 +00:00
7071131200
This is required by the default configuration of libav being brought over from meta-oe. Changes from the meta-oe recipe: * Update to the latest revision from the stable branch (upstream does not seem to provide stable releases.) * Add LICENSE_FLAGS = "commercial" * Enable PIC to fix text relocation warnings and disable warning for i586 (since PIC can't be used there) * Make SUMMARY value slightly shorter * Indent SRC_URI consistently with other recipes in OE-Core (From OE-Core rev: a3ca077285003fbc04d134e875a58a745271e47f) Signed-off-by: Paul Eggleton <paul.eggleton@linux.intel.com> Signed-off-by: Saul Wold <sgw@linux.intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
53 lines
1.3 KiB
BlitzBasic
53 lines
1.3 KiB
BlitzBasic
SUMMARY = "A free software library and application for encoding video streams into the H.264/MPEG-4 AVC format"
|
|
HOMEPAGE = "http://www.videolan.org/developers/x264.html"
|
|
|
|
LICENSE = "GPLv2"
|
|
LICENSE_FLAGS = "commercial"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f"
|
|
|
|
DEPENDS = "yasm-native"
|
|
|
|
SRC_URI = "git://git.videolan.org/x264.git \
|
|
file://don-t-default-to-cortex-a9-with-neon.patch \
|
|
"
|
|
|
|
SRCREV = "585324fee380109acd9986388f857f413a60b896"
|
|
|
|
PV = "r2265+git${SRCPV}"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
inherit lib_package pkgconfig
|
|
|
|
X264_DISABLE_ASM = ""
|
|
X264_DISABLE_ASM_armv4 = "--disable-asm"
|
|
X264_DISABLE_ASM_armv5 = "--disable-asm"
|
|
|
|
EXTRA_OECONF = '--prefix=${prefix} \
|
|
--host=${HOST_SYS} \
|
|
--cross-prefix=${TARGET_PREFIX} \
|
|
--sysroot=${STAGING_DIR_TARGET} \
|
|
--enable-shared \
|
|
--enable-static \
|
|
--disable-lavf \
|
|
--disable-swscale \
|
|
--enable-pic \
|
|
${X264_DISABLE_ASM} \
|
|
'
|
|
|
|
do_configure() {
|
|
./configure ${EXTRA_OECONF}
|
|
}
|
|
|
|
# Get rid of -e
|
|
EXTRA_OEMAKE = ""
|
|
AS = "${TARGET_PREFIX}gcc"
|
|
|
|
do_install() {
|
|
oe_runmake install DESTDIR=${D}
|
|
}
|
|
|
|
# PIC can't be enabled for 32-bit x86
|
|
INSANE_SKIP_${PN}_append_i586 = " textrel"
|
|
|