mirror of
git://git.yoctoproject.org/poky
synced 2026-04-02 02:49:11 +00:00
78193f7a83
(From OE-Core rev: a26cdcc31b97b5eed545b9859bee8b5c098d394b) Signed-off-by: Ankur Tyagi <ankur.tyagi85@gmail.com> Signed-off-by: Mathieu Dubois-Briand <mathieu.dubois-briand@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org> (cherry picked from commit f86c38b13121788fe6a654df04800d24b2b28b61) Signed-off-by: Ankur Tyagi <ankur.tyagi85@gmail.com> [YC: logs: https://git.kernel.org/pub/scm/linux/kernel/git/wens/wireless-regdb.git/log/?h=master-2026-02-04] Signed-off-by: Yoann Congal <yoann.congal@smile.fr> Signed-off-by: Paul Barker <paul@pbarker.dev>
44 lines
1.6 KiB
BlitzBasic
44 lines
1.6 KiB
BlitzBasic
SUMMARY = "Wireless Central Regulatory Domain Database"
|
|
HOMEPAGE = "https://wireless.wiki.kernel.org/en/developers/regulatory/crda"
|
|
SECTION = "net"
|
|
LICENSE = "ISC"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=07c4f6dea3845b02a18dc00c8c87699c"
|
|
|
|
SRC_URI = "https://www.kernel.org/pub/software/network/${BPN}/${BP}.tar.xz"
|
|
SRC_URI[sha256sum] = "0ff48a5cd9e9cfe8e815a24e023734919e9a3b7ad2f039243ad121cf5aabf6c6"
|
|
|
|
inherit bin_package allarch
|
|
|
|
do_install() {
|
|
install -d -m0755 ${D}${nonarch_libdir}/crda
|
|
install -d -m0755 ${D}${sysconfdir}/wireless-regdb/pubkeys
|
|
install -m 0644 regulatory.bin ${D}${nonarch_libdir}/crda/regulatory.bin
|
|
install -m 0644 wens.key.pub.pem ${D}${sysconfdir}/wireless-regdb/pubkeys/wens.key.pub.pem
|
|
|
|
install -m 0644 -D regulatory.db ${D}${nonarch_base_libdir}/firmware/regulatory.db
|
|
install -m 0644 regulatory.db.p7s ${D}${nonarch_base_libdir}/firmware/regulatory.db.p7s
|
|
}
|
|
|
|
# Install static regulatory DB in /lib/firmware for kernel to load.
|
|
# This requires Linux kernel >= v4.15.
|
|
# For kernel <= v4.14, inherit the kernel_wireless_regdb.bbclass
|
|
# (in meta-networking) in kernel's recipe.
|
|
PACKAGES = "${PN}-static ${PN}"
|
|
RCONFLICTS:${PN} = "${PN}-static"
|
|
|
|
FILES:${PN}-static = " \
|
|
${nonarch_base_libdir}/firmware/regulatory.db \
|
|
${nonarch_base_libdir}/firmware/regulatory.db.p7s \
|
|
"
|
|
|
|
# Native users might want to use the source of regulatory DB.
|
|
# This is for example used by Linux kernel <= v4.14 and
|
|
# kernel_wireless_regdb.bbclass in meta-networking.
|
|
do_install:append:class-native() {
|
|
install -m 0644 -D db.txt ${D}${libdir}/crda/db.txt
|
|
}
|
|
|
|
RSUGGESTS:${PN} = "crda"
|
|
|
|
BBCLASSEXTEND = "native"
|