mirror of
git://git.yoctoproject.org/poky
synced 2026-04-02 02:49:11 +00:00
941c3ac5a8
Handles CVE-2024-8354. Drop patch included in (backported to) this release. Reference: * https://security-tracker.debian.org/tracker/CVE-2024-8354 (From OE-Core rev: f9d2e0155df2fe799e5edd0b52097ee284930ba5) Signed-off-by: Peter Marko <peter.marko@siemens.com> Signed-off-by: Mathieu Dubois-Briand <mathieu.dubois-briand@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
33 lines
1.1 KiB
BlitzBasic
33 lines
1.1 KiB
BlitzBasic
BPN = "qemu"
|
|
|
|
require qemu-native.inc
|
|
|
|
# As some of the files installed by qemu-native and qemu-system-native
|
|
# are the same, we depend on qemu-native to get the full installation set
|
|
# and avoid file clashes
|
|
DEPENDS += "glib-2.0-native zlib-native pixman-native qemu-native"
|
|
|
|
EXTRA_OECONF:append = " --target-list=${@get_qemu_system_target_list(d)}"
|
|
|
|
PACKAGECONFIG ??= "fdt alsa kvm pie slirp png pixman sdl \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'opengl', 'virglrenderer epoxy', '', d)} \
|
|
"
|
|
|
|
# Handle distros such as CentOS 5 32-bit that do not have kvm support
|
|
PACKAGECONFIG:remove = "${@'kvm' if not os.path.exists('/usr/include/linux/kvm.h') else ''}"
|
|
|
|
do_install:append() {
|
|
install -Dm 0755 ${UNPACKDIR}/powerpc_rom.bin ${D}${datadir}/qemu
|
|
|
|
# The following is also installed by qemu-native
|
|
rm -f ${D}${datadir}/qemu/trace-events-all
|
|
rm -rf ${D}${datadir}/qemu/keymaps
|
|
rm -rf ${D}${datadir}/icons/
|
|
rm -rf ${D}${includedir}/qemu-plugin.h
|
|
|
|
# Install qmp.py to be used with testimage
|
|
install -d ${D}${libdir}/qemu-python/qmp/
|
|
install -D ${S}/python/qemu/qmp/* ${D}${libdir}/qemu-python/qmp/
|
|
}
|
|
|