mirror of
git://git.yoctoproject.org/poky
synced 2026-10-02 16:42:04 +00:00
944897dc66
Changelog: =========== - tablet: Remove unnecessary scale factor on REL_HWHEEL_HI_RES - quirks: add quirk for Minisforum V3 touchpad dwt - quirks: add quirk for the Minisforum V3 volume keys - quirks: add quirk for the LG gram 14 2023 Touchpad - doc/user: document ModelTouchpadPhantomClicks quirk - Fix typo in documentation comment (From OE-Core rev: a72c963b12d209f95a5c7c413956eb5e413f0bb9) Signed-off-by: Wang Mingyu <wangmy@fujitsu.com> Signed-off-by: Mathieu Dubois-Briand <mathieu.dubois-briand@bootlin.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
50 lines
1.9 KiB
BlitzBasic
50 lines
1.9 KiB
BlitzBasic
SUMMARY = "Library to handle input devices in Wayland compositors"
|
|
DESCRIPTION = "libinput is a library to handle input devices in Wayland \
|
|
compositors and to provide a generic X.Org input driver. It provides \
|
|
device detection, device handling, input device event processing and \
|
|
abstraction so minimize the amount of custom input code compositors need to \
|
|
provide the common set of functionality that users expect."
|
|
HOMEPAGE = "http://www.freedesktop.org/wiki/Software/libinput/"
|
|
SECTION = "libs"
|
|
|
|
LICENSE = "MIT"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=bab4ac7dc1c10bc0fb037dc76c46ef8a"
|
|
|
|
DEPENDS = "libevdev udev mtdev"
|
|
|
|
SRC_URI = "git://gitlab.freedesktop.org/libinput/libinput.git;protocol=https;branch=main \
|
|
file://run-ptest \
|
|
"
|
|
SRCREV = "3402f380019dc4f882e1d8627029607aca3f4be6"
|
|
S = "${WORKDIR}/git"
|
|
|
|
UPSTREAM_CHECK_REGEX = "libinput-(?P<pver>\d+\.\d+\.(?!9\d+)\d+)"
|
|
|
|
inherit meson pkgconfig lib_package ptest
|
|
|
|
# Patch out build directory, otherwise it leaks into ptest binary
|
|
do_configure:append() {
|
|
sed -i -e "s,${WORKDIR},,g" config.h
|
|
if [ -e "litest-config.h" ]; then
|
|
sed -i -e "s,${WORKDIR},,g" litest-config.h
|
|
fi
|
|
}
|
|
|
|
PACKAGECONFIG ??= "${@bb.utils.contains('PTEST_ENABLED', '1', 'tests', '', d)}"
|
|
PACKAGECONFIG[libwacom] = "-Dlibwacom=true,-Dlibwacom=false,libwacom"
|
|
PACKAGECONFIG[gui] = "-Ddebug-gui=true,-Ddebug-gui=false,cairo gtk+3 wayland-native"
|
|
PACKAGECONFIG[tests] = "-Dtests=true -Dinstall-tests=true,-Dtests=false -Dinstall-tests=false,libcheck"
|
|
|
|
UDEVDIR = "`pkg-config --variable=udevdir udev`"
|
|
|
|
EXTRA_OEMESON += "-Dudev-dir=${UDEVDIR} \
|
|
-Ddocumentation=false \
|
|
-Dzshcompletiondir=no"
|
|
|
|
# package name changed in 1.8.1 upgrade: make sure package upgrades work
|
|
RPROVIDES:${PN} = "libinput"
|
|
RREPLACES:${PN} = "libinput"
|
|
RCONFLICTS:${PN} = "libinput"
|
|
|
|
FILES:${PN}-ptest += "${libexecdir}/libinput/libinput-test-suite"
|