mirror of
git://git.yoctoproject.org/poky
synced 2026-10-02 17:03:55 +00:00
ca8d3f1494
(From OE-Core rev: c3d863f4f989461c61e7d61259423fe0e8202eed) Signed-off-by: Carlos Rafael Giani <dv@pseudoterminal.org> Signed-off-by: Ross Burton <ross.burton@intel.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
49 lines
2.1 KiB
BlitzBasic
49 lines
2.1 KiB
BlitzBasic
SUMMARY = "VA-API support to GStreamer"
|
|
DESCRIPTION = "gstreamer-vaapi consists of a collection of VA-API \
|
|
based plugins for GStreamer and helper libraries: `vaapidecode', \
|
|
`vaapiconvert', and `vaapisink'."
|
|
|
|
REALPN = "gstreamer-vaapi"
|
|
|
|
LICENSE = "LGPLv2.1+"
|
|
LIC_FILES_CHKSUM = "file://COPYING.LIB;md5=4fbd65380cdd255951079008b364516c"
|
|
|
|
SRC_URI = "https://gstreamer.freedesktop.org/src/${REALPN}/${REALPN}-${PV}.tar.xz \
|
|
file://0001-gst-vaapi-Makefile.am-Add-EGL_CFLAGS-to-libgstvaapi-.patch \
|
|
"
|
|
|
|
SRC_URI[md5sum] = "c3aeaf8a7fdcbe37d9f40390b620775d"
|
|
SRC_URI[sha256sum] = "8f5e65cb96aa6e44ff80926366d4a6fef9b8da68a04bab4bf2cbed93941c74f0"
|
|
|
|
S = "${WORKDIR}/${REALPN}-${PV}"
|
|
DEPENDS = "libva gstreamer1.0 gstreamer1.0-plugins-base gstreamer1.0-plugins-bad"
|
|
|
|
inherit autotools pkgconfig gtk-doc distro_features_check upstream-version-is-even
|
|
|
|
REQUIRED_DISTRO_FEATURES ?= "opengl"
|
|
|
|
PACKAGES =+ "${PN}-tests"
|
|
|
|
# OpenGL packageconfig factored out to make it easy for distros
|
|
# and BSP layers to pick either glx, egl, or no GL. By default,
|
|
# try detecting X11 first, and if found (with OpenGL), use GLX,
|
|
# otherwise try to check if EGL can be used.
|
|
PACKAGECONFIG_GL ?= "${@bb.utils.contains('DISTRO_FEATURES', 'x11 opengl', 'glx', \
|
|
bb.utils.contains('DISTRO_FEATURES', 'opengl', 'egl', \
|
|
'', d), d)}"
|
|
|
|
PACKAGECONFIG ??= "drm \
|
|
${PACKAGECONFIG_GL} \
|
|
${@bb.utils.filter('DISTRO_FEATURES', 'wayland x11', d)}"
|
|
|
|
PACKAGECONFIG[drm] = "--enable-drm,--disable-drm,udev libdrm"
|
|
PACKAGECONFIG[egl] = "--enable-egl,--disable-egl,virtual/egl"
|
|
PACKAGECONFIG[glx] = "--enable-glx,--disable-glx,virtual/libgl"
|
|
PACKAGECONFIG[wayland] = "--enable-wayland,--disable-wayland,wayland"
|
|
PACKAGECONFIG[x11] = "--enable-x11,--disable-x11,virtual/libx11 libxrandr libxrender"
|
|
|
|
FILES_${PN} += "${libdir}/gstreamer-*/*.so"
|
|
FILES_${PN}-dbg += "${libdir}/gstreamer-*/.debug"
|
|
FILES_${PN}-dev += "${libdir}/gstreamer-*/*.la ${libdir}/gstreamer-*/*.a"
|
|
FILES_${PN}-tests = "${bindir}/*"
|