mirror of
git://git.yoctoproject.org/poky
synced 2026-09-07 04:08:58 +00:00
ca7096f88c
6.1 is a LTS kernel, and our next reference kernel. Some new features like rust support are not directly used, but will be available to start testing. (From OE-Core rev: 1a450283c85f7bbadcbbb8973d3c3d15a712abb3) Signed-off-by: Bruce Ashfield <bruce.ashfield@gmail.com> Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
71 lines
3.4 KiB
BlitzBasic
71 lines
3.4 KiB
BlitzBasic
KBRANCH ?= "v6.1/standard/base"
|
|
|
|
require recipes-kernel/linux/linux-yocto.inc
|
|
|
|
# board specific branches
|
|
KBRANCH:qemuarm ?= "v6.1/standard/arm-versatile-926ejs"
|
|
KBRANCH:qemuarm64 ?= "v6.1/standard/qemuarm64"
|
|
KBRANCH:qemumips ?= "v6.1/standard/mti-malta32"
|
|
KBRANCH:qemuppc ?= "v6.1/standard/qemuppc"
|
|
KBRANCH:qemuriscv64 ?= "v6.1/standard/base"
|
|
KBRANCH:qemuriscv32 ?= "v6.1/standard/base"
|
|
KBRANCH:qemux86 ?= "v6.1/standard/base"
|
|
KBRANCH:qemux86-64 ?= "v6.1/standard/base"
|
|
KBRANCH:qemumips64 ?= "v6.1/standard/mti-malta64"
|
|
|
|
SRCREV_machine:qemuarm ?= "09521916385d581a8ee0517f8279d28303f22d32"
|
|
SRCREV_machine:qemuarm64 ?= "6b919643ad199903450791493de5791556c032b7"
|
|
SRCREV_machine:qemumips ?= "0a86f820b067832e72b291c2310b0808618f66a6"
|
|
SRCREV_machine:qemuppc ?= "6b919643ad199903450791493de5791556c032b7"
|
|
SRCREV_machine:qemuriscv64 ?= "6b919643ad199903450791493de5791556c032b7"
|
|
SRCREV_machine:qemuriscv32 ?= "6b919643ad199903450791493de5791556c032b7"
|
|
SRCREV_machine:qemux86 ?= "6b919643ad199903450791493de5791556c032b7"
|
|
SRCREV_machine:qemux86-64 ?= "6b919643ad199903450791493de5791556c032b7"
|
|
SRCREV_machine:qemumips64 ?= "99437d8498c3e175f7e0f666e8a42fc942c65262"
|
|
SRCREV_machine ?= "6b919643ad199903450791493de5791556c032b7"
|
|
SRCREV_meta ?= "d2ea5dce4e8398b85b226c9b0f303584de8d9f30"
|
|
|
|
# set your preferred provider of linux-yocto to 'linux-yocto-upstream', and you'll
|
|
# get the <version>/base branch, which is pure upstream -stable, and the same
|
|
# meta SRCREV as the linux-yocto-standard builds. Select your version using the
|
|
# normal PREFERRED_VERSION settings.
|
|
BBCLASSEXTEND = "devupstream:target"
|
|
SRCREV_machine:class-devupstream ?= "094226ad94f471a9f19e8f8e7140a09c2625abaa"
|
|
PN:class-devupstream = "linux-yocto-upstream"
|
|
KBRANCH:class-devupstream = "v6.1/base"
|
|
|
|
SRC_URI = "git://git.yoctoproject.org/linux-yocto.git;name=machine;branch=${KBRANCH}; \
|
|
git://git.yoctoproject.org/yocto-kernel-cache;type=kmeta;name=meta;branch=yocto-6.1;destsuffix=${KMETA}"
|
|
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=6bc538ed5bd9a7fc9398086aedcd7e46"
|
|
LINUX_VERSION ?= "6.1"
|
|
|
|
DEPENDS += "${@bb.utils.contains('ARCH', 'x86', 'elfutils-native', '', d)}"
|
|
DEPENDS += "openssl-native util-linux-native"
|
|
DEPENDS += "gmp-native libmpc-native"
|
|
|
|
PV = "${LINUX_VERSION}+git${SRCPV}"
|
|
|
|
KMETA = "kernel-meta"
|
|
KCONF_BSP_AUDIT_LEVEL = "1"
|
|
|
|
KERNEL_DEVICETREE:qemuarmv5 = "versatile-pb.dtb"
|
|
|
|
COMPATIBLE_MACHINE = "^(qemuarm|qemuarmv5|qemuarm64|qemux86|qemuppc|qemuppc64|qemumips|qemumips64|qemux86-64|qemuriscv64|qemuriscv32)$"
|
|
|
|
# Functionality flags
|
|
KERNEL_EXTRA_FEATURES ?= "features/netfilter/netfilter.scc"
|
|
KERNEL_FEATURES:append = " ${KERNEL_EXTRA_FEATURES}"
|
|
KERNEL_FEATURES:append:qemuall=" cfg/virtio.scc features/drm-bochs/drm-bochs.scc cfg/net/mdio.scc"
|
|
KERNEL_FEATURES:append:qemux86=" cfg/sound.scc cfg/paravirt_kvm.scc"
|
|
KERNEL_FEATURES:append:qemux86-64=" cfg/sound.scc cfg/paravirt_kvm.scc"
|
|
KERNEL_FEATURES:append = " ${@bb.utils.contains("TUNE_FEATURES", "mx32", " cfg/x32.scc", "", d)}"
|
|
KERNEL_FEATURES:append = " ${@bb.utils.contains("DISTRO_FEATURES", "ptest", " features/scsi/scsi-debug.scc", "", d)}"
|
|
KERNEL_FEATURES:append = " ${@bb.utils.contains("DISTRO_FEATURES", "ptest", " features/gpio/mockup.scc", "", d)}"
|
|
KERNEL_FEATURES:append:powerpc =" arch/powerpc/powerpc-debug.scc"
|
|
KERNEL_FEATURES:append:powerpc64 =" arch/powerpc/powerpc-debug.scc"
|
|
KERNEL_FEATURES:append:powerpc64le =" arch/powerpc/powerpc-debug.scc"
|
|
|
|
INSANE_SKIP:kernel-vmlinux:qemuppc64 = "textrel"
|
|
|