mirror of
git://git.yoctoproject.org/poky
synced 2026-09-17 00:56:11 +00:00
f0f4ed9ba5
Changelog:
==========
[bug] Use two pairs of dns_db_t and dns_dbversion_t in a
catalog zone structure to avoid a race between the
dns__catz_update_cb() and dns_catz_dbupdate_callback()
functions. [GL #3907]
[bug] Make sure to revert the reconfigured zones to the
previous version of the view, when the new view
reconfiguration fails during the configuration of
one of the configured zones. [GL #3911]
[bug] Fix error path cleanup issues in dns_catz_new_zones()
and dns_catz_new_zone() functions. [GL #3900]
[bug] Unregister db update notify callback before detaching
from the previous db inside the catz update notify
callback. [GL #3777]
[func Run the catalog zone update process on the offload
threads. [GL #3881]
[func Add shutdown signaling for catalog zones. [GL !7571]
[func Add reference count tracing for dns_catz_zone_t and
dns_catz_zones_t. [GL !7570]
[bug] Detach 'rpzs' and 'catzs' from the previous view in
configure_rpz() and configure_catz(), respectively,
just after attaching it to the new view. [GL #3880]
[test Don't test HMAC-MD5 when not supported by libcrypto.
[GL #3871]
[bug] Fix RPZ reference counting error on shutdown in
dns__rpz_timer_cb(). [GL #3866]
[test Test various 'islands of trust' configurations when
using managed keys. [GL #3662]
[bug] Building against (or running with) libuv versions
1.35.0 and 1.36.0 is now a fatal error. The rules for
mixing and matching compile-time and run-time libuv
versions have been tightened for libuv versions between
1.35.0 and 1.40.0. [GL #3840]
[bug] dnssec-cds failed to cleanup properly. [GL #3831]
[bug] Source ports configured for query-source,
transfer-source, etc, were being ignored. (This
feature is deprecated, but it is not yet removed,
so the bug still needed fixing.) [GL #3790]
(From OE-Core rev: 51ab191224aa1320d622bf79184940afa3910d60)
Signed-off-by: Wang Mingyu <wangmy@fujitsu.com>
Signed-off-by: Alexandre Belloni <alexandre.belloni@bootlin.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
114 lines
4.2 KiB
BlitzBasic
114 lines
4.2 KiB
BlitzBasic
SUMMARY = "ISC Internet Domain Name Server"
|
|
HOMEPAGE = "https://www.isc.org/bind/"
|
|
DESCRIPTION = "BIND 9 provides a full-featured Domain Name Server system"
|
|
SECTION = "console/network"
|
|
|
|
LICENSE = "MPL-2.0"
|
|
LIC_FILES_CHKSUM = "file://COPYRIGHT;md5=d8cf7bd9c4fd5471a588e7e66e672408"
|
|
|
|
DEPENDS = "openssl libcap zlib libuv"
|
|
|
|
SRC_URI = "https://ftp.isc.org/isc/bind9/${PV}/${BPN}-${PV}.tar.xz \
|
|
file://conf.patch \
|
|
file://named.service \
|
|
file://bind9 \
|
|
file://generate-rndc-key.sh \
|
|
file://make-etc-initd-bind-stop-work.patch \
|
|
file://init.d-add-support-for-read-only-rootfs.patch \
|
|
file://bind-ensure-searching-for-json-headers-searches-sysr.patch \
|
|
file://0001-named-lwresd-V-and-start-log-hide-build-options.patch \
|
|
file://0001-avoid-start-failure-with-bind-user.patch \
|
|
"
|
|
|
|
SRC_URI[sha256sum] = "3b06b6390c1012dd3956b1479c73b2097c0b22207817e2e8aae352fd20e578c7"
|
|
|
|
UPSTREAM_CHECK_URI = "https://ftp.isc.org/isc/bind9/"
|
|
# follow the ESV versions divisible by 2
|
|
UPSTREAM_CHECK_REGEX = "(?P<pver>9.(\d*[02468])+(\.\d+)+(-P\d+)*)/"
|
|
|
|
# Issue only affects dhcpd with recent bind versions. We don't ship dhcpd anymore
|
|
# so the issue doesn't affect us.
|
|
CVE_CHECK_IGNORE += "CVE-2019-6470"
|
|
|
|
inherit autotools update-rc.d systemd useradd pkgconfig multilib_header update-alternatives
|
|
|
|
# PACKAGECONFIGs readline and libedit should NOT be set at same time
|
|
PACKAGECONFIG ?= "readline"
|
|
PACKAGECONFIG[httpstats] = "--with-libxml2=${STAGING_DIR_HOST}${prefix},--without-libxml2,libxml2"
|
|
PACKAGECONFIG[readline] = "--with-readline=readline,,readline"
|
|
PACKAGECONFIG[libedit] = "--with-readline=libedit,,libedit"
|
|
PACKAGECONFIG[dns-over-http] = "--enable-doh,--disable-doh,nghttp2"
|
|
|
|
EXTRA_OECONF = " --disable-devpoll --disable-auto-validation --enable-epoll \
|
|
--with-gssapi=no --with-lmdb=no --with-zlib \
|
|
--sysconfdir=${sysconfdir}/bind \
|
|
--with-openssl=${STAGING_DIR_HOST}${prefix} \
|
|
"
|
|
LDFLAGS:append = " -lz"
|
|
|
|
# dhcp needs .la so keep them
|
|
REMOVE_LIBTOOL_LA = "0"
|
|
|
|
USERADD_PACKAGES = "${PN}"
|
|
USERADD_PARAM:${PN} = "--system --home ${localstatedir}/cache/bind --no-create-home \
|
|
--user-group bind"
|
|
|
|
INITSCRIPT_NAME = "bind"
|
|
INITSCRIPT_PARAMS = "defaults"
|
|
|
|
SYSTEMD_SERVICE:${PN} = "named.service"
|
|
|
|
do_install:append() {
|
|
|
|
install -d -o bind "${D}${localstatedir}/cache/bind"
|
|
install -d "${D}${sysconfdir}/bind"
|
|
install -d "${D}${sysconfdir}/init.d"
|
|
install -m 644 ${S}/conf/* "${D}${sysconfdir}/bind/"
|
|
install -m 755 "${S}/init.d" "${D}${sysconfdir}/init.d/bind"
|
|
|
|
# Install systemd related files
|
|
install -d ${D}${sbindir}
|
|
install -m 755 ${WORKDIR}/generate-rndc-key.sh ${D}${sbindir}
|
|
install -d ${D}${systemd_system_unitdir}
|
|
install -m 0644 ${WORKDIR}/named.service ${D}${systemd_system_unitdir}
|
|
sed -i -e 's,@BASE_BINDIR@,${base_bindir},g' \
|
|
-e 's,@SBINDIR@,${sbindir},g' \
|
|
${D}${systemd_system_unitdir}/named.service
|
|
|
|
install -d ${D}${sysconfdir}/default
|
|
install -m 0644 ${WORKDIR}/bind9 ${D}${sysconfdir}/default
|
|
|
|
if ${@bb.utils.contains('DISTRO_FEATURES', 'systemd', 'true', 'false', d)}; then
|
|
install -d ${D}${sysconfdir}/tmpfiles.d
|
|
echo "d /run/named 0755 bind bind - -" > ${D}${sysconfdir}/tmpfiles.d/bind.conf
|
|
fi
|
|
}
|
|
|
|
CONFFILES:${PN} = " \
|
|
${sysconfdir}/bind/named.conf \
|
|
${sysconfdir}/bind/named.conf.local \
|
|
${sysconfdir}/bind/named.conf.options \
|
|
${sysconfdir}/bind/db.0 \
|
|
${sysconfdir}/bind/db.127 \
|
|
${sysconfdir}/bind/db.empty \
|
|
${sysconfdir}/bind/db.local \
|
|
${sysconfdir}/bind/db.root \
|
|
"
|
|
|
|
ALTERNATIVE:${PN}-utils = "nslookup"
|
|
ALTERNATIVE_LINK_NAME[nslookup] = "${bindir}/nslookup"
|
|
ALTERNATIVE_PRIORITY = "100"
|
|
|
|
PACKAGE_BEFORE_PN += "${PN}-utils"
|
|
FILES:${PN}-utils = "${bindir}/host ${bindir}/dig ${bindir}/mdig ${bindir}/nslookup ${bindir}/nsupdate"
|
|
FILES:${PN}-dev += "${bindir}/isc-config.h"
|
|
FILES:${PN} += "${sbindir}/generate-rndc-key.sh"
|
|
|
|
PACKAGE_BEFORE_PN += "${PN}-libs"
|
|
# special arrangement below due to
|
|
# https://github.com/isc-projects/bind9/commit/0e25af628cd776f98c04fc4cc59048f5448f6c88
|
|
FILES_SOLIBSDEV = "${libdir}/*[!0-9].so ${libdir}/libbind9.so"
|
|
FILES:${PN}-libs = "${libdir}/named/*.so* ${libdir}/*-${PV}.so"
|
|
|
|
DEV_PKG_DEPENDENCY = ""
|