mirror of
git://git.yoctoproject.org/poky
synced 2026-10-07 15:35:46 +00:00
96a6df7b14
License-Update: A typo "httpss->https" fixed in Copyright.
Drop deprecated patches.
Inherit autotools-brokensep instead of autotools, there are some
generated headers in ${B} that referring to ${S}.
(From OE-Core rev: 061c99fb84b25cca8783efa66851b52c74126063)
Signed-off-by: Ming Liu <liu.ming50@gmail.com>
Signed-off-by: Mathieu Dubois-Briand <mathieu.dubois-briand@bootlin.com>
Signed-off-by: Richard Purdie <richard.purdie@linuxfoundation.org>
47 lines
1.7 KiB
BlitzBasic
47 lines
1.7 KiB
BlitzBasic
SUMMARY = "Multiplexing terminal manager"
|
|
DESCRIPTION = "Screen is a full-screen window manager \
|
|
that multiplexes a physical terminal between several \
|
|
processes, typically interactive shells."
|
|
HOMEPAGE = "http://www.gnu.org/software/screen/"
|
|
BUGTRACKER = "https://savannah.gnu.org/bugs/?func=additem&group=screen"
|
|
|
|
SECTION = "console/utils"
|
|
|
|
LICENSE = "GPL-3.0-or-later"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=c678957b0c8e964aa6c70fd77641a71e \
|
|
file://screen.h;endline=26;md5=b8dc717c9a3dba842ae6c44ca0f73f52 \
|
|
"
|
|
|
|
DEPENDS = "ncurses virtual/crypt \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'pam', 'libpam', '', d)}"
|
|
RDEPENDS:${PN} = "base-files"
|
|
|
|
SRC_URI = "${GNU_MIRROR}/screen/screen-${PV}.tar.gz \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'pam', 'file://screen.pam', '', d)} \
|
|
"
|
|
|
|
SRC_URI[sha256sum] = "f04a39d00a0e5c7c86a55338808903082ad5df4d73df1a2fd3425976aed94971"
|
|
|
|
inherit autotools-brokensep texinfo
|
|
|
|
PACKAGECONFIG ??= ""
|
|
PACKAGECONFIG[utempter] = "ac_cv_header_utempter_h=yes,ac_cv_header_utempter_h=no,libutempter,"
|
|
|
|
EXTRA_OECONF = "--with-pty-mode=0620 --with-pty-group=5 --with-system_screenrc=${sysconfdir}/screenrc \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'pam', '--enable-pam', '--disable-pam', d)}"
|
|
|
|
do_install:append () {
|
|
install -D -m 644 ${S}/etc/etcscreenrc ${D}/${sysconfdir}/screenrc
|
|
if [ "${@bb.utils.filter('DISTRO_FEATURES', 'pam', d)}" ]; then
|
|
install -D -m 644 ${UNPACKDIR}/screen.pam ${D}/${sysconfdir}/pam.d/screen
|
|
fi
|
|
}
|
|
|
|
pkg_postinst:${PN} () {
|
|
grep -q "^${bindir}/screen$" $D${sysconfdir}/shells || echo ${bindir}/screen >> $D${sysconfdir}/shells
|
|
}
|
|
|
|
pkg_postrm:${PN} () {
|
|
printf "$(grep -v "^${bindir}/screen$" $D${sysconfdir}/shells)\n" > $D${sysconfdir}/shells
|
|
}
|