SUMMARY = "Helium default image"
LICENSE = "MIT"

#DISTRO := "helium"

inherit core-image
inherit image-buildinfo

IMAGE_INSTALL += " \
	packagegroup-system-base \
	packagegroup-system-tools \
	packagegroup-hardening \
	packagegroup-helium-base \
	packagegroup-helium-tools \
"

IMAGE_FEATURES += " \
	ssh-server-dropbear \
	package-management \
"
# debug-tweaks are enabled by default in local.conf, disable this for Helium images
IMAGE_FEATURES:remove = "debug-tweaks"

# default user/password config
inherit extrausers
HELIUM_UID = "1000"
HELIUM_GID = "1000"
HELIUM_PASSWD = "\$1\$BFS1T2Yb\$umbig5XRyIOVrFGS1phly0"
HELIUM_ROOT_PASSWD = "\$1\$IgVsR0cM\$WUkg3Nd.1bAGLWjf9.t.3/"
EXTRA_USERS_PARAMS = "\
	groupadd -g ${HELIUM_GID} helium; \
	useradd -p '${HELIUM_PASSWD}' -g helium -u ${HELIUM_UID} helium; \
	usermod -p '${HELIUM_ROOT_PASSWD}' root; \
"

# image manifest - list of installed packages
ROOTFS_POSTUNINSTALL_COMMAND += ";add_image_manifest"
add_image_manifest() {
	cp ${IMAGE_MANIFEST} ${IMAGE_ROOTFS}/etc/image_manifest
}

IMAGE_FSTYPES = "cpio.gz"
# Apparently we're using initamfs as rootfs (?)
# Allow it to grow big (limited to 4GB for now)
INITRAMFS_MAXSIZE = "4194304"