# Ox64
#
# BouffaloLab BL808
# T-Head C906 CPU
# riscv64-imafdc sv39

# Helium specific
MACHINE_FRIENDLY_NAME = "Ox64"
MACHINE_NUM_CORES = "1"

# Architecture tuning
DEFAULTTUNE = "riscv64"
require conf/machine/include/riscv/tune-riscv.inc
TUNE_CCARGS:append = "-mabi=lp64d -mtune=thead-c906"

# Available machine features
MACHINE_FEATURES = "ext2 ext3 serial vfat wifi"
MACHINE_FEATURES:remove = " rtc"

# Kernel and device tree
KERNEL_IMAGETYPE = "Image"
PREFERRED_PROVIDER_virtual/kernel = "linux-yocto"
PREFERRED_VERSION_virtual/kernel = "6.6%"
KERNEL_DEVICETREE = "bouffalolab/bl808-pine64-ox64.dtb"
MACHINE_EXTRA_RRECOMMENDS = "kernel-modules kernel-devicetree"

# Serial console
SERIAL_CONSOLES ?= "2000000;ttyS0"
SERIAL_CONSOLES_CHECK = "${SERIAL_CONSOLES}"

# Bootloader
EXTRA_IMAGEDEPENDS += "virtual/bootloader"
PREFERRED_PROVIDER_virtual/bootloader ?= "u-boot"
UBOOT_MACHINE = "ox64_d0_defconfig"

# OpenSBI
RISCV_SBI_PLAT ?= "generic"

# wic SD card image
IMAGE_FSTYPES += " wic"
WKS_FILE = "ox64.wks"
do_image_wic[depends] += "virtual/bootloader:do_deploy"
IMAGE_BOOT_FILES ?= "boot.scr ${KERNEL_IMAGETYPE} ${KERNEL_DEVICETREE} extlinux*.conf;extlinux/"
MACHINE_ESSENTIAL_EXTRA_RDEPENDS += "kernel-image kernel-devicetree"